iniciar-programa

define-nueva-instruccion recolecta(t) como inicio
    si frente-libre o izquierda-libre entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recolecta(sucede(t));
        fin sino inicio
            si frente-bloqueado entonces repetir 2 veces gira-izquierda;
            si frente-libre entonces avanza;
            recolecta(t);
        fin;
    fin sino inicio
        repetir t veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion checa como inicio
            repetir 3 veces gira-izquierda;
            repetir 2 veces avanza;
            coge-zumbador;
            repetir 2 veces gira-izquierda;
            si no-junto-a-zumbador entonces inicio
                repetir 2 veces avanza;
                gira-izquierda;
                recolecta(0);
                apagate;
            fin;
            repetir 2 veces avanza;
            gira-izquierda;
fin;

define-nueva-instruccion avanzar(z) como inicio
    si frente-libre y no si-es-cero(z) entonces inicio
        deja-zumbador;
        repetir z veces inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                si derecha-bloqueada entonces inicio
                    repetir 2 veces gira-izquierda;
                    avanza;
                fin sino inicio
                    checa;
                    avanza;
                fin;
            fin;
        fin;

        avanzar(precede(z));
    fin sino inicio
    si frente-bloqueado entonces inicio
        si izquierda-libre entonces inicio
            repetir 2 veces gira-izquierda;
            avanzar(z);
        fin sino inicio
            checa;
            avanzar(z);
        fin;
    fin;
    fin;
fin;


define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin sino inicio
        avanza;
        gira-izquierda;
        mientras algun-zumbador-en-la-mochila hacer avanzar(x);
    fin;
fin;

    inicia-ejecucion
        gira-izquierda;
        repetir 2 veces avanza;
        si no-junto-a-zumbador entonces apagate;
        repetir 2 veces gira-izquierda;
        avanza;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
