iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion mide como inicio
        si frente-libre entonces inicio
            avanza;
            mide;
            repetir 2 veces deja-zumbador;
        fin sino inicio
            oeste;
            corre;
        fin;
    fin;
    define-nueva-instruccion multiplica(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplica(x);
            repetir x veces deja-zumbador;
        fin sino inicio
            sur;
            corre;
        fin;
    fin;
    define-nueva-instruccion vueltas(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            vueltas(sucede(x));
        fin sino inicio
            norte;
            repetir 2 veces avanza;
            multiplica(x);
        fin;
    fin;
    define-prototipo-instruccion leer(x);
    define-nueva-instruccion mueve como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve;
            deja-zumbador;
        fin sino inicio
            oeste;
            corre;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion resta(x) como inicio
        si no si-es-cero(x) y junto-a-zumbador entonces inicio
            repetir x veces si junto-a-zumbador entonces coge-zumbador;
            este;
            avanza;
            deja-zumbador;
            oeste;
            avanza;
            resta(precede(x));
        fin sino inicio
            si si-es-cero(x) entonces inicio
                norte;
                avanza;
                sur;
                leer(0);
            fin sino inicio
                si no-junto-a-zumbador entonces inicio
                    este;
                    avanza;
                    mueve;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion leer(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            leer(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            sur;
            avanza;
            resta(x);
        fin;
    fin;
    inicia-ejecucion
        mide;
        vueltas(0);
        norte;
        avanza;
        sur;
        leer(0);

        apagate;
    termina-ejecucion
finalizar-programa
