iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta (sucede(n));
        fin
        sino inicio
            gira (2);
            mientras frente-libre hacer
                avanza;
            norte;
            avanza;
            avanza;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                sur;
                avanza;
                avanza;
                repetir n veces
                    deja-zumbador;
                repetir n veces
                    deja-zumbador;
                repetir 2 veces
                    coge-zumbador;
                norte;
                avanza;
                avanza;
            fin;
            sur;
            avanza;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion llena (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llena (sucede(n));
        fin
        sino inicio
            sur;
            avanza;
            este;
            mientras frente-libre hacer inicio
                repetir n veces
                    deja-zumbador;
                avanza;
            fin;
            repetir n veces
                deja-zumbador;
            oeste;
            mientras frente-libre hacer
                avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion contar (n) como inicio
        si no si-es-cero (n) y junto-a-zumbador entonces inicio
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            norte;
            avanza;
            este;
            avanza;
            deja-zumbador;
            oeste;
            avanza;
            sur;
            avanza;
            contar (precede(n));
        fin;
    fin;
    define-nueva-instruccion pasos (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasos (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            sur;
            avanza;
            mientras junto-a-zumbador hacer inicio
                contar (n);
                norte;
                avanza;
                pasos (0);
            fin;
        fin;
    fin;
    define-nueva-instruccion total (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            total (sucede(n));
        fin
        sino inicio
            oeste;
            avanza;
            sur;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        este;
        cuenta (1);
        norte;
        avanza;
        pasos (0);
        norte;
        avanza;
        este;
        avanza;
        total (0);
        apagate;
    termina-ejecucion
finalizar-programa