iniciar-programa
    define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
    define-nueva-instruccion derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion deja(v) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            deja(sucede(v));
        fin
        sino inicio
            avanza;
            repetir v veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion compra1(x) como inicio
        si frente-libre entonces inicio
            avanza;
            compra1(sucede(sucede(x)));
        fin
        sino inicio
            vuelta;
            mientras izquierda-bloqueada hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            repetir 2 veces avanza;
            repetir x veces coge-zumbador;
            vuelta;
            repetir 3 veces avanza;
            repetir x veces deja-zumbador;
            vuelta;
        fin;
    fin;
    define-nueva-instruccion compra2(w) como inicio
        si frente-libre entonces inicio
            avanza;
            compra2(sucede(sucede(sucede(w))));
        fin
        sino inicio
            vuelta;
            mientras izquierda-bloqueada hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            repetir 2 veces avanza;
            repetir w veces coge-zumbador;
            vuelta;
            repetir 2 veces avanza;
            repetir w veces deja-zumbador;
            vuelta;
        fin;
    fin;
    define-nueva-instruccion compara(z) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(z));
        fin
        sino inicio
            avanza;
            repetir z veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin
                sino inicio
                    avanza;
                    repetir z veces deja-zumbador;
                    apagate;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                avanza;
                repetir z veces deja-zumbador;
                vuelta;
                avanza;
                vuelta;
                deja(0);
                apagate;
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer gira-izquierda;
        repetir 2 veces avanza;
        gira-izquierda;
        repetir 2 veces avanza;
        derecha;
        compra1(0);
        avanza;
        gira-izquierda;
        repetir 5 veces avanza;
        derecha;
        compra2(0);
        vuelta;
        compara(0);
        apagate;
    termina-ejecucion
finalizar-programa
