iniciar-programa
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
    define-nueva-instruccion buscar(x) como inicio
        este;
        avanza;
        mientras no-junto-a-zumbador hacer avanza;
        repetir x veces coge-zumbador;
        repetir 2 veces gira-izquierda;
        avanzar;
        si junto-a-zumbador entonces inicio
            norte;
            avanza;
        fin;
        repetir x veces deja-zumbador;
    fin;
    define-nueva-instruccion cambia como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si orientado-al-norte entonces inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    sur;
                fin sino inicio
                    oeste;
                fin;
            fin sino inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                fin sino inicio
                    oeste;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion saca-medida(x) como inicio
        si no-orientado-al-oeste entonces inicio
            cambia;
            saca-medida(sucede(x));
        fin sino inicio
            sur;
            avanzar;
            oeste;
            avanzar;
            sur;
            avanzar;
            buscar(x);
        fin

    fin;
    define-nueva-instruccion ir1 como inicio
        este;
        repetir 2 veces avanza;
        norte;
        mientras derecha-libre hacer avanza;
        sur;
        avanza;
        este;                            
        avanza;
        norte;
        saca-medida(0);
    fin;
    define-nueva-instruccion ir2 como inicio
        este;
        repetir 2 veces avanza;
        norte;
        mientras derecha-libre hacer avanza;
        mientras derecha-bloqueada hacer avanza;
        mientras derecha-libre hacer avanza;
        sur;
        avanza;
        este;
        avanza;
        norte;
        saca-medida(0);
    fin;
    define-nueva-instruccion mayor(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(n));
        fin sino inicio
            sur;
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            repetir n veces deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        ir1;
        ir2;
        mayor(0);
        apagate;
    termina-ejecucion
finalizar-programa
