iniciar-programa
    define-nueva-instruccion gd como repetir 3 veces gira-izquierda;
    define-nueva-instruccion mv como repetir 2 veces gira-izquierda;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino inicio
            mv;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            repetir 4 veces avanza;
            repetir n veces coge-zumbador;
            mv;
            repetir 4 veces avanza;
            repetir n veces deja-zumbador;
            mv;
            avanza;
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            gira-izquierda;
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                mv;
                avanza;
                gira-izquierda;
                coge-zumbador;
                compara(sucede(n));
            fin
            sino inicio
                mv;
                avanza;
                mv;
                cuenta(n);
            fin;
        fin
        sino inicio
            gira-izquierda;
            avanza;
            si junto-a-zumbador entonces cuenta(n)
            sino inicio
                mv;
                avanza;
                gira-izquierda;
                repetir 4 veces avanza;
                repetir n veces coge-zumbador;
                mv;
                repetir 4 veces avanza;
                repetir n veces deja-zumbador;
                mv;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion area(n) como inicio
        si orientado-al-norte entonces inicio
           si frente-libre entonces inicio
               avanza;
               area(sucede(n));
           fin
           sino inicio
               si derecha-libre entonces inicio
                   gd;
                   avanza;
                   gd;
                   mientras frente-libre hacer avanza;
                   mv;
                   area(sucede(n));
               fin
               sino inicio
                   gd;
                   repetir 2 veces inicio
                       gd;
                       mientras frente-libre hacer avanza;
                   fin;
                   gira-izquierda;
                   mientras frente-libre hacer avanza;
                   gira-izquierda;
                   repetir 4 veces avanza;
                   repetir sucede(n) veces coge-zumbador;
                   mv;
                   repetir 4 veces avanza;
                   gd;
                   mientras junto-a-zumbador hacer avanza;
                   repetir sucede(n) veces deja-zumbador;
                   mv;
                   si frente-libre entonces avanza;
                   gira-izquierda;
               fin;
           fin;
        fin;
    fin;
    inicia-ejecucion
    mientras no-orientado-al-norte hacer gira-izquierda;
    mientras frente-libre hacer inicio
        avanza;
        si frente-bloqueado entonces inicio
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                si derecha-bloqueada entonces inicio
                    mv;
                    avanza;
                    gd;
                fin
                sino inicio
                    mv;
                    avanza;
                    gira-izquierda;
                fin;
            fin
            sino gira-izquierda;
            si frente-libre entonces inicio
                mientras frente-libre hacer avanza;
                gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
        fin;
    fin;
    gira-izquierda;
    avanza;
    repetir 2 veces inicio
        gd;
        avanza;
    fin;
    gira-izquierda;
    area(0);
    mientras no-orientado-al-norte hacer gira-izquierda;
    mientras frente-libre hacer inicio
        avanza;
        si frente-bloqueado entonces inicio
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                si derecha-bloqueada entonces inicio
                    mv;
                    avanza;
                    gd;
                fin
                sino inicio
                    mv;
                    avanza;
                    gira-izquierda;
                fin;
            fin
            sino gira-izquierda;
            si frente-libre entonces inicio
                mientras frente-libre hacer avanza;
                gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
        fin;
    fin;
    gira-izquierda;
    avanza;
    gd;
    repetir 2 veces inicio
        mientras derecha-libre hacer avanza;
        mientras derecha-bloqueada hacer avanza;
    fin;
    mv;
    avanza;
    mientras izquierda-bloqueada hacer avanza;
    gira-izquierda;
    avanza;
    gira-izquierda;
    area(0);
    compara(0);
        apagate;
    termina-ejecucion
finalizar-programa
