iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion encontrar como
        inicio
           mientras derecha-libre hacer
               inicio
                  si frente-libre entonces avanza sino
                      inicio
                         norte;
                         avanza;
                         este;
                         mientras frente-libre hacer avanza;
                         oeste;
                      fin;
               fin;
        fin;

    define-nueva-instruccion contar(x) como
        inicio
           si derecha-bloqueada entonces
               inicio
                  si frente-libre entonces
                      inicio
                         avanza;
                         contar(sucede(x));
                      fin;
               fin sino
                   inicio
                      si no-junto-a-zumbador entonces
                          inicio
                             norte;
                             repetir 3 veces avanza;
                             este;
                             mientras frente-libre hacer avanza;
                             oeste;
                             encontrar;
                             mientras derecha-bloqueada y frente-libre hacer avanza;
                             repetir x veces repetir 2 veces deja-zumbador;
                             este;
                             si frente-libre entonces avanza;
                             mientras izquierda-bloqueada y frente-libre hacer avanza;
                             oeste;
                             mientras derecha-libre hacer avanza;
                          fin sino
                              inicio
                                 repetir x veces repetir 3 veces si junto-a-zumbador entonces coge-zumbador;
                                 si junto-a-zumbador entonces
                                     inicio
                                        repetir x veces repetir 3 veces deja-zumbador;
                                     fin sino repetir x veces repetir 3 veces deja-zumbador;
                                 este;
                                 avanza;
                                 mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                                 oeste;
                                 avanza;
                                 mientras junto-a-zumbador hacer coge-zumbador;
                              fin;
                   fin;
        fin;

    inicia-ejecucion
        este;
        repetir 4 veces avanza;
        repetir 300 veces coge-zumbador;
        mientras frente-libre hacer avanza;
        oeste;
        encontrar;
        repetir 2 veces contar(0);
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
