iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion barda(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            barda(sucede(n));
        fin sino
        inicio
            repetir n veces deja-zumbador;
            avanza;
            repetir n veces coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion poste(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            poste(sucede(n));
        fin sino
        inicio
            avanza;
            norte;
            avanza;
            mientras junto-a-zumbador hacer
            inicio
                repetir n veces coge-zumbador;
                sur;
                avanza;
                deja-zumbador;
                norte;
                avanza;
            fin;
            sur;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion perimetro(n) como
    inicio
        si derecha-libre entonces repetir 3 veces gira-izquierda;
        si no-junto-a-zumbador entonces
        inicio
            avanza;
            perimetro(sucede(n));
        fin sino
        inicio
            coge-zumbador;
            este;
            avanza;
            repetir sucede(n) veces deja-zumbador;
            avanza;
            sur;
            avanza;
            repetir sucede(n) veces deja-zumbador;
            oeste;
            repetir 2 veces avanza;
        fin;
    fin;

    define-nueva-instruccion bardando como
    inicio
        este;
        avanza;
        norte;
        avanza;
        deja-zumbador;
        avanza;
        perimetro(0);
        este;
        poste(0);
        barda(0);
    fin;

    inicia-ejecucion
        bardando;
        apagate;
    termina-ejecucion
finalizar-programa
