iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion posicionarse como
  inicio
    norte;
    avanza;
    este;
    avanza;
    deja-zumbador;
    avanza;
  fin;

define-nueva-instruccion perimetro(n) como
  inicio
    si no junto-a-zumbador entonces
      inicio
        avanza;
        si izquierda-libre y no junto-a-zumbador entonces
          inicio
            gira-izquierda;
            avanza;
          fin;
        perimetro(sucede(n));
      fin
    sino
      inicio
        coge-zumbador;
        avanza;
        este;
        avanza;
        repetir n veces deja-zumbador;
        repetir 4 veces deja-zumbador;
         avanza;
        repetir n veces deja-zumbador;
        repetir 4 veces deja-zumbador;
      fin;
  fin;

define-nueva-instruccion dividir(n) como
  inicio
   si junto-a-zumbador entonces
     inicio
      coge-zumbador;
      dividir(sucede(n));
     fin
   sino
     inicio
       este;
       avanza;
       mientras junto-a-zumbador hacer
         inicio
           repetir n veces coge-zumbador;
           norte;
           avanza;
           deja-zumbador;
           sur;
           avanza;
         fin;
     fin;
  fin;

define-nueva-instruccion mover(n) como
  inicio
   si junto-a-zumbador entonces
     inicio
       coge-zumbador;
       mover(sucede(n));
     fin
   sino                              
     inicio
       sur;
       avanza;
       repetir n veces deja-zumbador;
       este;
       avanza;
       repetir n veces coge-zumbador;
     fin;
  fin;
    inicia-ejecucion
          posicionarse;
          perimetro(0);
          oeste;
          repetir 2 veces avanza;
          dividir(0);
          norte;
          avanza;
          mover(0);
        apagate;
    termina-ejecucion
finalizar-programa
