iniciar-programa
    define-nueva-instruccion super-avanza como mientras frente-libre hacer avanza;
    define-nueva-instruccion gira-derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion mide-hor(n) como inicio
        si derecha-bloqueada entonces inicio
            avanza;
            mide-hor(sucede(n));
        fin sino inicio
            gira-derecha;
            super-avanza;
            oeste;
            super-avanza;
            repetir 2 veces repetir sucede(sucede(n)) veces deja-zumbador;
            norte;
            avanza;
            repetir 2 veces repetir sucede(sucede(n)) veces deja-zumbador;
            sur;
            avanza;
        fin;
    fin;
   define-nueva-instruccion mide-ver(n) como inicio
        si derecha-bloqueada entonces inicio
            avanza;
            mide-ver(sucede(n));
        fin sino inicio
            gira-derecha;
            avanza;
            mide-hor(n);
        fin;
    fin;
    define-nueva-instruccion distancia(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            distancia(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            oeste;
            avanza;
            mientras junto-a-zumbador hacer inicio
                repetir precede(n) veces inicio
                    si junto-a-zumbador entonces coge-zumbador;
                fin;
                si junto-a-zumbador entonces coge-zumbador;
                este;
                repetir 2 veces avanza;
                deja-zumbador;
                oeste;
                repetir 2 veces avanza;
            fin;
       fin;
   fin;
   define-nueva-instruccion responde como inicio
       si junto-a-zumbador entonces inicio
           coge-zumbador;
           responde;
           deja-zumbador;
       fin sino inicio
           sur;
           avanza;
           este;
           repetir 3 veces avanza;
       fin;
   fin;
   define-nueva-instruccion vallas(n) como inicio
       si junto-a-zumbador entonces inicio
           coge-zumbador;
           vallas(sucede(n));
       fin sino inicio
           repetir n veces deja-zumbador;
           norte;
           avanza;
           oeste;
           repetir 2 veces avanza;
           repetir n veces coge-zumbador;
           responde;
       fin;
   fin;
    inicia-ejecucion
        este;
        avanza;
        norte;
        repetir 2 veces avanza;
        mide-ver(0);
        este;
        avanza;
        distancia(0);
        este;
        repetir 2 veces avanza;
        vallas(0);
        apagate;
    termina-ejecucion
finalizar-programa
