iniciar-programa
    define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion coloca(n) como inicio
      si no-junto-a-zumbador entonces inicio
        deja-zumbador;
        repetir n veces inicio
          si izquierda-bloqueada entonces inicio
            avanza;
          fin sino inicio
            gira-izquierda;
            avanza;
          fin;
        fin;
        coloca(n);
        deja-zumbador;
      fin sino inicio
        sur;
        avanza;
        este;
        avanza;
      fin;
    fin;

    define-nueva-instruccion distancia(n) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        distancia(sucede(n));
      fin sino inicio
        repetir n veces inicio
          deja-zumbador;
        fin;
        norte;
        avanza;
        este;
        deja-zumbador;
        repetir n veces inicio
          avanza;
        fin;
        coloca(n);
      fin;
    fin;

    define-nueva-instruccion recorre(n) como inicio
      si no-junto-a-zumbador entonces inicio
        deja-zumbador;
        avanza;
        recorre(sucede(n));
      fin sino inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
          sur;
          avanza;
          este;
          avanza;
          avanza;
          repetir n veces deja-zumbador;
          apagate;
        fin sino inicio
          deja-zumbador;
          si izquierda-bloqueada entonces inicio
            avanza;
            recorre(n);
          fin sino inicio
            gira(1);
            avanza;
            recorre(n);
          fin;
        fin;
      fin;
    fin;

    define-nueva-instruccion barda como inicio
      norte;
      avanza;
      oeste;
      avanza;
      este;
      deja-zumbador;
      avanza;
      recorre(0);
    fin;

    inicia-ejecucion
        este;
        avanza;
        distancia(0);
        deja-zumbador;
        barda;
        deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
