iniciar-programa
    define-nueva-instruccion g(n) como
        repetir n veces
             gira-izquierda;
    define-nueva-instruccion avance como
    inicio
        si derecha-libre entonces
        inicio
            g(3);
        fin;
        avanza;

    fin;
    define-nueva-instruccion cp(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            repetir n veces
                avance;
            cp(n);
            deja-zumbador;
        fin
        sino
        inicio
            mientras no-orientado-al-oeste hacer
                g(1);
            mientras frente-libre hacer
                avanza;
            mientras no-orientado-al-sur hacer
                g(1);
            mientras frente-libre hacer
                avanza;
            mientras no-orientado-al-oeste hacer
                g(1);
            mientras frente-libre hacer
                avanza;
            mientras no-orientado-al-sur hacer
                g(1);
            mientras frente-libre hacer
                avanza;
            mientras no-orientado-al-este hacer
                g(1);
            repetir 2 veces
                avanza;
        fin;
    fin;
    define-nueva-instruccion barda(n) como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            deja-zumbador;

            repetir n veces
                avance;
            barda(n);
        fin;
    fin;
    define-nueva-instruccion pasos(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            pasos(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            avanza;
            repetir precede(n) veces
                avance;
            cp(n);
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            g(1);
            avanza;
            deja-zumbador;
            avanza;
            repetir precede(n) veces
                avance;
            barda(n);
        fin;
    fin;
    define-nueva-instruccion mult(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            mult(sucede(n));
        fin
        sino
        inicio
            avanza;
            mientras junto-a-zumbador hacer
            inicio
                coge-zumbador;
                avanza;
                repetir n veces
                    deja-zumbador;
                g(2);
                avanza;
                g(3);
                avanza;
                deja-zumbador;
                g(2);
                avanza;
                g(1);
            fin;
        fin;
    fin;
    define-nueva-instruccion ult(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ult(sucede(n));
        fin
        sino
        inicio
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer
            g(1);
        avanza;
        cuenta(0);
        g(1);
        avanza;
        g(2);
        pasos(0);
        g(2);
        avanza;
        coge-zumbador;
        g(2);
        mult(0);
        g(1);
        avanza;
        g(2);
        ult(0);
        apagate;
    termina-ejecucion
finalizar-programa
