iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion siguiente como inicio
        si derecha-bloqueada entonces inicio
            avanza;
        fin sino inicio
            gira(3);
            avanza;
        fin;
    fin;

    define-nueva-instruccion colocar(x) como inicio
        si no(si-es-cero(x)) entonces inicio
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                siguiente;
                colocar(precede(x));
            fin;
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                repetir 2 veces deja-zumbador;
                siguiente;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(distancia) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(distancia));
        fin sino inicio
            repetir distancia veces deja-zumbador;
            avanza;
            repetir 2 veces deja-zumbador;
            avanza;
            mientras no-junto-a-zumbador hacer inicio
                colocar(precede(distancia));
            fin;
        fin;
    fin;

    define-nueva-instruccion contar_Beepers como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                siguiente;
                contar_Beepers;
                (*cantidad de postes*)
                oeste;
                avanza;
                deja-zumbador;
                este;
                avanza;
            fin sino inicio
                siguiente;
                contar_Beepers;
                (*cantidad de vallas*)
                deja-zumbador;
            fin;
        fin sino inicio
            (*Nos acomodamos en la posicion para empezar a dejar las vallas y postes*)
            sur;
            mientras frente-libre hacer avanza;
            este;
            repetir 2 veces avanza;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        norte;
        cuenta(0);
        norte;
        avanza;
        contar_Beepers;
        apagate;
    termina-ejecucion
finalizar-programa
