iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion cuanto como inicio
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            si izquierda-bloqueada entonces inicio
                avanza;
            fin
            sino inicio
                gira (1);
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion rodear (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si izquierda-bloqueada entonces inicio
                avanza;
            fin
            sino inicio
                gira (1);
                avanza;
            fin;
            rodear (sucede(n));
        fin
        sino inicio
            sur;
            mientras frente-libre hacer
                avanza;
            oeste;
            mientras frente-libre hacer
                avanza;
            este;
            repetir n veces
                deja-zumbador;
            norte;
            avanza;
            repetir n veces
                deja-zumbador;
            sur;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion division (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            division (sucede(n));
        fin
        sino inicio
            oeste;
            avanza;
            mientras junto-a-zumbador hacer inicio
                repetir n veces
                    coge-zumbador;
                este;
                avanza;
                deja-zumbador;
                oeste;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion resta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta (sucede(n));
        fin
        sino inicio
            avanza;
            repetir n veces
                deja-zumbador;
            oeste;
            mientras frente-libre hacer
                avanza;
            norte;
            avanza;
            repetir n veces
                coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion bardas (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            bardas (sucede(n));
        fin
        sino inicio
            sur;
            mientras frente-libre hacer
                avanza;
            este;
            mientras no-junto-a-zumbador y frente-libre hacer
                avanza;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        este;
        avanza;
        norte;
        avanza;
        este;
        avanza;
        cuanto;
        rodear (0);
        avanza;
        division (0);
        este;
        avanza;
        resta (0);
        bardas (0);
        apagate;
    termina-ejecucion
finalizar-programa