iniciar-programa
    define-prototipo-instruccion cuenta-los-postes(p);
    define-nueva-instruccion adelante como inicio
        si izquierda-bloqueada entonces inicio
            avanza;
        fin
        sino inicio
            gira-izquierda;
            avanza;
        fin;
    fin;
    define-nueva-instruccion perimetro como inicio
        si no-junto-a-zumbador o no-orientado-al-sur entonces inicio
            adelante;
            perimetro;
            si frente-libre entonces inicio
                coge-zumbador;
                avanza;
                repetir 3 veces gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion rodea(r) como inicio
        si orientado-al-norte entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                rodea(sucede(r));
            fin;
            si no-junto-a-zumbador y orientado-al-norte entonces inicio
                repetir r veces deja-zumbador;
                repetir 2 veces avanza;
                repetir 2 veces gira-izquierda;
                deja-zumbador;
                repetir r veces adelante;
                mientras no-junto-a-zumbador o no-orientado-al-sur hacer inicio
                    deja-zumbador;
                    repetir r veces adelante;
                fin;
                cuenta-los-postes(r);
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta-los-postes(p) como inicio
        si junto-a-zumbador y derecha-libre entonces inicio
            coge-zumbador;
            repetir p veces adelante;
            cuenta-los-postes(p);
        fin;
        si orientado-al-sur entonces inicio
            repetir 2 veces avanza;
            gira-izquierda;
            avanza;
        fin;
        deja-zumbador;
    fin;
    define-nueva-instruccion pasa como inicio
        si junto-a-zumbador y orientado-al-oeste entonces inicio
            coge-zumbador;
            pasa;
        fin;
        si no junto-a-zumbador y orientado-al-oeste entonces inicio
            repetir 2 veces gira-izquierda;
            repetir 3 veces avanza;
        fin;
        deja-zumbador;
    fin;
    define-nueva-instruccion resta(r) como inicio
        si junto-a-zumbador y orientado-al-oeste entonces inicio
            coge-zumbador;
            resta(sucede(r));
        fin;
        si no-junto-a-zumbador y orientado-al-oeste entonces inicio
            repetir 2 veces avanza;
            repetir r veces coge-zumbador;
            repetir 2 veces gira-izquierda;
            repetir 2 veces avanza;
            repetir r veces deja-zumbador;
            repetir 2 veces gira-izquierda;
            repetir 2 veces avanza;
            pasa;
            coge-zumbador;
            apagate;
        fin;
    fin;
    inicia-ejecucion
        repetir 3 veces gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
        deja-zumbador;
        avanza;
        perimetro;
        deja-zumbador;
        gira-izquierda;
        avanza;
        gira-izquierda;
        rodea(0);
        coge-zumbador;
        repetir 2 veces gira-izquierda;
        resta(0);
        apagate;
    termina-ejecucion
finalizar-programa
