iniciar-programa

define-nueva-instruccion norte como inicio
mientras no-orientado-al-norte hacer gira-izquierda;
fin;

define-nueva-instruccion este como inicio
mientras no-orientado-al-este hacer gira-izquierda;
fin;

define-nueva-instruccion oeste como inicio
mientras no-orientado-al-oeste hacer gira-izquierda;
fin;

define-nueva-instruccion sur como inicio
mientras no-orientado-al-sur hacer gira-izquierda;
fin;

define-nueva-instruccion gira(z) como inicio
    repetir z veces gira-izquierda;
fin;

define-nueva-instruccion mueve(z) como inicio
    repetir z veces avanza;
fin;

define-nueva-instruccion regresa como inicio
    norte;
    avanza;
    oeste;
    mientras frente-libre hacer avanza;
    sur;
    mientras frente-libre hacer avanza;
    si junto-a-zumbador entonces inicio
        este;
        avanza;
    fin;

fin;

define-nueva-instruccion linea como inicio
    norte;
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
        fin;
    sur;
    mientras frente-libre hacer avanza;
    este;
fin;

define-nueva-instruccion cuenta como inicio
    mientras frente-libre o junto-a-zumbador hacer inicio
        linea;
        si frente-libre entonces avanza;
    fin;
fin;

define-nueva-instruccion ini1 como inicio
    mueve(5);
    este;
    avanza;
    sur;
    avanza;
    este;
    cuenta;
    regresa;
     mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
fin;

define-nueva-instruccion ini2 como inicio
    mueve(5);
    este;
    mueve(7);
    sur;
    avanza;
    este;
    cuenta;
    regresa;
    si frente-bloqueado entonces inicio
       este;
       avanza;
    fin;
     mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
fin;

define-nueva-instruccion compara(w) como inicio
   si no si-es-cero (w) entonces inicio
       si junto-a-zumbador entonces inicio
           coge-zumbador;
           compara(precede(w));
       fin sino inicio
           repetir w veces deja-zumbador;
       fin;
   fin;

fin;

define-nueva-instruccion mayor(q) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        mayor(sucede(q));
    fin sino inicio
        avanza;
        compara(q);
    fin;
fin;

define-nueva-instruccion mitad como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        coge-zumbador;
        mitad;
        deja-zumbador;
    fin;
fin;

define-nueva-instruccion proceso como inicio
mayor(0);
mitad;
fin;


    inicia-ejecucion
    ini1;
    norte;
    ini2;
    oeste;
    proceso;
        apagate;
    termina-ejecucion
finalizar-programa
