iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion mitad como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            si algun-zumbador-en-la-mochila entonces deja-zumbador;
            mitad;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion acomodar como inicio
        mientras orientado-al-norte hacer inicio
            mientras junto-a-zumbador hacer inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                avanza;
            fin;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            si frente-libre entonces inicio
                avanza;
                gira(1);
            fin sino inicio
                mitad;
                gira(1);
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                sal-de-instruccion;
            fin;
        fin;
    fin;

    define-nueva-instruccion subir como inicio
        repetir 5 veces avanza;
        gira(3);
        avanza;
        gira(3);
        avanza;
        gira(2);
    fin;

    define-nueva-instruccion dejar_resultado como inicio
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        apagate;
    fin;

    define-nueva-instruccion comparar(x) como inicio
        si no(si-es-cero(x)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                comparar(precede(x));
            fin sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                repetir x veces coge-zumbador;
                dejar_resultado;
            fin;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                gira(1);
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                gira(2);
                avanza;
                gira(1);
                mientras junto-a-zumbador hacer coge-zumbador;
                dejar_resultado;
            fin sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                dejar_resultado;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(x));
        fin sino inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            comparar(x);
        fin;
    fin;

    inicia-ejecucion
        subir;
        acomodar;
        gira(3);
        repetir 3 veces avanza;
        gira(3);
        avanza;
        gira(2);
        acomodar;
        gira(1);
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
