iniciar-programa
    define-nueva-instruccion gira-derecha como
        repetir 3 veces
            gira-izquierda;
    define-nueva-instruccion media-vuelta como
        repetir 2 veces
            gira-izquierda;
    define-nueva-instruccion junta como inicio
        mientras frente-libre o junto-a-zumbador hacer inicio
            si junto-a-zumbador entonces inicio
                gira-izquierda;
                mientras junto-a-zumbador hacer inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    si frente-libre entonces
                        avanza;
               fin;
               media-vuelta;
               mientras frente-libre hacer
                   avanza;
               gira-izquierda;
            fin;
            si frente-libre entonces
               avanza;
       fin;
       gira-izquierda;
       avanza;
       mientras algun-zumbador-en-la-mochila hacer
           deja-zumbador;
    fin;
    define-nueva-instruccion balanza(n) como
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            balanza(sucede(n));
        fin
        sino inicio
            avanza;
            repetir n veces
                si junto-a-zumbador y no-orientado-al-norte entonces
                    coge-zumbador
                sino inicio
                    si no-orientado-al-norte entonces
                        gira-derecha;
                    deja-zumbador;
                fin;
            si no-junto-a-zumbador entonces
                gira-izquierda;
        fin;
    define-nueva-instruccion diferencia como
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge-zumbador;
            diferencia;
            deja-zumbador;
        fin
        sino inicio
            si no-orientado-al-oeste entonces
                gira-izquierda;
            mientras frente-libre hacer
                avanza;
            gira-izquierda;
            mientras frente-libre hacer
                avanza;
        fin;

    inicia-ejecucion
        repetir 5 veces
            avanza;
        gira-derecha;
        avanza;
        gira-derecha;
        avanza;
        gira-izquierda;
        junta;
        gira-derecha;
        repetir 3 veces
            avanza;
        gira-derecha;
        avanza;
        gira-izquierda;
        junta;
        mientras junto-a-zumbador hacer
            coge-zumbador;
        gira-izquierda;
        repetir 5 veces
            avanza;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        balanza(0);
        si junto-a-zumbador entonces
            diferencia;
        apagate;
    termina-ejecucion
finalizar-programa
