iniciar-programa
define-nueva-instruccion gira(a) como inicio
    repetir a veces inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion norte como inicio
    mientras no-orientado-al-norte hacer inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion toca-pared como inicio
    mientras frente-libre hacer inicio
        avanza;
    fin;
fin;
define-nueva-instruccion esquina como inicio
    norte;
    gira(2);
    toca-pared;
    gira(3);
    toca-pared;
    norte;
fin;
define-nueva-instruccion comprueba(q) como inicio
    si si-es-cero(q) entonces inicio
        si junto-a-zumbador entonces inicio
            norte;
        fin
        sino inicio
            norte;
            gira(3);
        fin;
    fin
    sino inicio
        si no-junto-a-zumbador entonces inicio
            norte;
            gira-izquierda;
        fin
        sino inicio
            coge-zumbador;
            comprueba(precede(q));
            deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion elimina(n) como inicio
    mientras frente-libre hacer inicio
        si junto-a-zumbador entonces inicio
            comprueba(n);
        fin;
        si orientado-al-este entonces inicio
            si frente-libre entonces inicio
                avanza;
            fin;
        fin
        sino inicio
            norte;
            gira(3);
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;
    comprueba(n);
    si no-orientado-al-este entonces inicio
        gira(3);
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion escoge(m) como inicio
    si junto-a-zumbador entonces inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        escoge(sucede(m));
    fin
    sino inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                escoge(m);
            fin
            sino inicio
                esquina;
                comprueba(m);
                si orientado-al-oeste o orientado-al-este entonces inicio
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                    fin;
                    repetir m veces inicio
                        deja-zumbador;
                    fin;
                fin;
                norte;
                repetir 5 veces inicio
                    avanza;
                fin;
                gira(3);
                mientras frente-libre y no-junto-a-zumbador hacer inicio
                    avanza;
                fin;
                si junto-a-zumbador entonces inicio
                    escoge(0);
                fin;
            fin;
        fin
        sino inicio
            esquina;
            comprueba(m);
            si orientado-al-oeste o orientado-al-este entonces inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                repetir m veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin
    sino inicio
        repetir 4 veces inicio
            avanza;
        fin;
        gira(3);
        elimina(x);
        gira(2);
        toca-pared;
        gira(2);
        escoge(0);
    fin;
fin;
    inicia-ejecucion
        esquina;
        avanza;
        si junto-a-zumbador entonces inicio
            cuenta(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
