iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
    fin;

    define-nueva-instruccion color(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            color(precede(n));
        fin sino inicio
            si si-es-cero(n) y no junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion ropa(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ropa(sucede(n));
        fin sino inicio
            norte;
            repetir 4 veces avanza;
            este;
            mientras frente-libre hacer inicio
                color(n);
                avanza;
            fin;
            color(n);
        fin;
    fin;

    define-nueva-instruccion recoger(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                recoger(0);
            fin sino inicio
                ir11;
            fin;
            si si-es-cero(precede(n)) entonces inicio
                deja-zumbador;
            fin sino inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion formar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            formar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanzA;
                formar(0);
            fin;
            si no si-es-cero(n) entonces inicio
                ir11;
                repetir precede(n) veces inicio
                    avanza;
                fin;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion mayor como inicio
        si frente-libre entonces inicio
            avanza;
            mayor;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
        deja-zumbador;
    fin;

    define-nueva-instruccion arriba como inicio
        norte;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si junto-a-zumbador entonces
        mayor;
    fin;

    inicia-ejecucion
        norte;
        avanza;
        ropa(0);
        oeste;
        recoger(0);
        sur;
        formar(0);
        arribA;
        apagate;
    termina-ejecucion
finalizar-programa
 