iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion compara(n) como
    inicio
        si no si-es-cero(n) entonces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                compara(precede(n));
            fin;
        fin sino
        inicio
            si no-junto-a-zumbador entonces
            inicio
                sur;
                avanza;
                deja-zumbador;
                norte;
                avanza;
                este;
            fin sino mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino
        inicio
            mientras no-junto-a-zumbador hacer avanza;
            este;
            mientras frente-libre o (frente-bloqueado y junto-a-zumbador) hacer
            inicio
                compara(n);
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion junta(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si frente-libre entonces avanza;
            junta(sucede(n));
        fin sino
        inicio
            repetir n veces deja-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;

    define-nueva-instruccion mayor(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            mayor(sucede(n));
        fin sino
        inicio
            mientras frente-libre hacer
            inicio
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces
                inicio
                    repetir n veces si junto-a-zumbador entonces coge-zumbador;
                fin;
                si junto-a-zumbador entonces mayor(n);
            fin;
            sur;
            mientras frente-libre hacer avanza;
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            repetir n veces deja-zumbador;
            apagate;
         fin;
    fin;

    inicia-ejecucion
        norte;
        avanza;
        cuenta(0);
        sur;
        avanza;
        oeste;
        mientras frente-libre hacer
        inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            junta(0);
        fin;
        este;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mayor(0);
        apagate;
    termina-ejecucion
finalizar-programa

