iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
    fin;
    define-nueva-instruccion vacia como inicio
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            compara(sucede(n));
        fin sino inicio
            repetir n veces inicio
                coge-zumbador;
            fin;
            norte;
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            norte;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin sino inicio
                    sur;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                sur;
            fin;
            mientras junto-a-zumbador hacer coge-zumbador;
            si orientado-al-norte  entonces inicio
                sur;
                avanza;
                deja-zumbador;
                norte;
                avanza;
                avanza;
                vacia;
                repetir n veces inicio
                    coge-zumbador;
                fin;
                sur;
                avanza;
                este;
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
            si orientado-al-sur entonces inicio
                norte;
                avanza;
                vacia;
                repetir n veces inicio
                    coge-zumbador;
                fin;
                sur;
                avanza;
                este;
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion junta como inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
            fin;
        fin;
        si algun-zumbador-en-la-mochila entonces inicio
            sur;
            avanza;
            oeste;
            si frente-libre entonces inicio
                avanza;
            fin;
            vacia;
            norte;
            avanza;
            este;
            si frente-libre entonces inicio
                avanza;
            fin;    
        fin;
        si frente-libre entonces inicio
            mientras no-junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
        fin;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            sur;
        fin;
    fin;
    define-nueva-instruccion mayor(j) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(j));
        fin sino inicio
            mientras no-junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si junto-a-zumbador entonces inicio
                repetir j veces inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                    fin;
                fin;
                repetir j veces inicio
                    deja-zumbador;
                fin;
                si algun-zumbador-en-la-mochila entonces inicio
                    sur;
                    avanza;
                    vacia;
                    norte;
                    avanza;
                    este;
                fin;
            fin;
            si frente-bloqueado entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                ir11;
                vacia;
                apagate;
            fin;
        fin;
    fin;
     inicia-ejecucion
        ir11;
        norte;
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir 4 veces inicio
            avanza;
        fin;
        este;
        mientras junto-a-zumbador hacer inicio
            compara(0);
        fin;
        vacia;
        sur;
        avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        mientras no-orientado-al-sur hacer inicio
            junta;
        fin;
        sur;
        avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        mientras no-junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        mientras junto-a-zumbador hacer inicio
            mayor(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
