iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ir11 como inicio
        norte;
        repetir 8 veces si frente-libre entonces avanza;
        oeste;
        corre;
        sur;
        corre;
        norte;
        avanza;
    fin;
    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            quita(precede(n));
        fin sino inicio
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
            fin sino inicio
                si si-es-cero(n) entonces inicio
                    norte;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion leer(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            leer(sucede(n));
        fin sino inicio
            repetir 4 veces avanza;
            este;
            mientras no-orientado-al-oeste hacer inicio
                quita(n);
                si orientado-al-norte entonces inicio
                    este;
                    repetir n veces deja-zumbador;
                fin;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    oeste;
                fin;
            fin;

        fin;
    fin;
    define-nueva-instruccion amontona como inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
            amontona;
            deja-zumbador;
        fin sino inicio
            oeste;
            corre;
            este;
            mientras junto-a-zumbador hacer avanza;
        fin;
    fin;
    define-nueva-instruccion grupos como inicio
        corre;
        este;
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                amontona;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    oeste;
                fin;
            fin sino inicio
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    oeste;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion agarra(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            agarra(sucede(n));
        fin sino inicio
            si frente-libre entonces  inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
            si junto-a-zumbador y no-orientado-al-oeste entonces inicio
                repetir n veces si junto-a-zumbador entonces coge-zumbador;
                repetir n veces deja-zumbador;
                agarra(0);
            fin sino inicio
                oeste;
                corre;
                sur;
                corre;
                repetir n veces deja-zumbador;
            fin;    
        fin;
    fin;
    inicia-ejecucion
        ir11;
        leer(0);
        grupos;
        corre;
        este;
        agarra(0);
        apagate;
    termina-ejecucion
finalizar-programa

