iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion buscar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        buscar(sucede(a));
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            buscar(0);
        fin;
        si si-es-cero(a) entonces inicio
            mientras no-orientado-al-oeste hacer gira(1);
            mientras frente-libre hacer avanza;
            gira(2);
        fin sino inicio
            mientras no-orientado-al-este hacer gira(1);
            si no-junto-a-zumbador entonces deja-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;
fin;

define-nueva-instruccion comprobar(b) como inicio
    repetir  b veces inicio
        si junto-a-zumbador y orientado-al-este entonces inicio
            coge-zumbador;
        fin sino inicio
            mientras no-orientado-al-oeste hacer  gira(1);
            deja-zumbador;
        fin;
    fin;
    si no-junto-a-zumbador y orientado-al-este entonces inicio
        deja-zumbador;
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        si no-orientado-al-este entonces gira(2);
    fin;
fin;

define-nueva-instruccion color(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        color(sucede(x));
    fin sino inicio
        repetir 4 veces avanza;
        gira(3);
        comprobar(x);
        mientras frente-libre hacer inicio
            avanza;
            comprobar(x);
        fin;
        gira(2);
        buscar(0);
    fin;
fin;

define-nueva-instruccion final(z) como inicio
    si no(si-es-cero(z)) entonces inicio
        si si-es-cero(precede(z)) entonces inicio
            deja-zumbador;
            apagate;
        fin sino inicio
            repetir 2 veces deja-zumbador;
            final(precede(precede(z)));
        fin;
    fin sino inicio
        apagate;
    fin;
fin;

define-nueva-instruccion llevar(c) como inicio
    si frente-libre entonces inicio
        avanza;
        llevar(sucede(c));
    fin sino inicio
        gira(1);
        mientras frente-libre hacer avanza;
        final(sucede(c));
    fin;
fin;

    inicia-ejecucion

    avanza;
    color(0);
    mientras junto-a-zumbador y frente-libre hacer avanza;
    gira(2);
    si no-junto-a-zumbador y frente-libre entonces avanza;
    si no-junto-a-zumbador entonces apagate;
    llevar(0);

        apagate;
    termina-ejecucion
finalizar-programa
