iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;

    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                juntar(0);
            fin sino inicio
                sur;
                mientras frente-libre hacer inicio
                    avanzA;
                fin;
                norte;
            fin;
            si si-es-cero(n) entonces inicio
                deja-zumbador;
            fin sino inicio
                si frente-libre entonces inicio
                    avanzA;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion formar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            formar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                formar(0);
            fin;
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            norte;
            si no si-es-cero(n) entonces inicio
                repetir precede(n) veces inicio
                    avanza;
                fin;
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion tomar1(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar1(precede(n));
        fin sino inicio
            si si-es-cero(n) entonces inicio
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    sur;
                fin;
            fin sino inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    sur;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion tomar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(sucede(n));
        fin sino inicio
            mientras no-junto-a-zumbador hacer inicio
                avanza;
            fin;
            este;
            mientras no-orientado-al-sur hacer inicio
                tomar1(n);
            fin;
        fin;
    fin;

    define-nueva-instruccion ropa(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ropa(sucede(n));
        fin sino inicio
            mientras frente-libre hacer inicio
                avanzA;
            fin;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        avanzA;
        tomar(0);
        oeste;
        juntar(0);
        sur;
        formar(0);
        mientras frente-libre hacer inicio
            avanzA;
        fin;
        sur;
        mientras no-junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        ropa(0);

        apagate;
    termina-ejecucion
finalizar-programa
