iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion compara(numero) como inicio
        si no si-es-cero(numero) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara(precede(numero));
            fin;
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion mayor(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(x));
        fin sino inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                repetir x veces inicio
                    si junto-a-zumbador entonces coge-zumbador;
                fin;
                mayor(x);
            fin sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                repetir x veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion acomodar_Elementos(x) como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            repetir x veces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    acomodar_Elementos(sucede(x));
                fin sino inicio
                    acomodar_Elementos(0);
                fin;
            fin sino inicio
                gira(2);
                mayor(0);
            fin;
        fin sino inicio
            gira(2);
            mayor(0);
        fin;
    fin;

    define-nueva-instruccion cuenta(numero) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(numero));
        fin sino inicio
            mientras no-junto-a-zumbador hacer avanza;
            gira(3);
            mientras junto-a-zumbador hacer inicio
                compara(numero);
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    gira(2);
                    acomodar_Elementos(0);
                fin;
            fin;
        fin;
    fin;                                                

    define-nueva-instruccion ir_Por_Beepers como inicio
        mientras frente-libre hacer avanza;
        gira(3);
        repetir 2 veces avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        repetir 1000 veces coge-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(1);
        repetir 2 veces avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;

    inicia-ejecucion
        ir_Por_Beepers;
        avanza;
        cuenta(0);
    termina-ejecucion
finalizar-programa
