iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        norte;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        sur;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion baja como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            baja;
            deja-zumbador;
        fin
        sino inicio
            sur;
            avanza;
            norte;
        fin;
    fin;
    define-nueva-instruccion coloca (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coloca (sucede(n));
        fin
        sino inicio
            mientras frente-libre hacer
                avanza;
            norte;
            repetir n veces
                avanza;
            deja-zumbador;
            sur;
            mientras frente-libre hacer
                avanza;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin
            sino inicio
                norte;
            fin;
        fin;
    fin;
    define-nueva-instruccion sube (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sube (sucede(n));
        fin
        sino inicio
            repetir n veces
                avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion tam (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si frente-libre entonces inicio
                avanza;
                tam (sucede(n));
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                gira (2);
                mientras junto-a-zumbador hacer
                    avanza;
                repetir n veces
                    deja-zumbador;
                deja-zumbador;
                avanza;
            fin;
        fin
        sino inicio
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (2);
            mientras junto-a-zumbador hacer
                avanza;
            repetir n veces
                deja-zumbador;
            avanza;
        fin;
    fin;
    define-nueva-instruccion mayor como inicio
        mientras frente-libre hacer inicio
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si junto-a-zumbador entonces inicio
                tam (0);
            fin;
        fin;
    fin;
    define-nueva-instruccion cubeta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cubeta (sucede(n));
        fin
        sino inicio
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (3);
            repetir n veces
                avanza;
            si no-junto-a-zumbador entonces inicio
                repetir n veces
                    deja-zumbador;
            fin;
            gira (2);
            repetir n veces
                avanza;
            gira (1);
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
        fin;
    fin;
    define-nueva-instruccion resultado (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resultado (sucede(n));
        fin
        sino inicio
            mientras frente-libre hacer
                avanza;
            este;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion tendedero como inicio
        orienta;
        avanza;
        baja;
        mientras derecha-libre hacer inicio
            repetir 5 veces
                avanza;
            sur;
            coloca (0);
        fin;
        repetir 5 veces
            avanza;
        sur;
        coloca (0);
        orienta;
        sube (0);
        mayor;
        gira (2);
        mientras frente-libre hacer
            avanza;
        gira (2);
        mientras junto-a-zumbador hacer inicio
            si junto-a-zumbador entonces inicio
                cubeta (0);
            fin;
        fin;
        gira (2);
        mientras frente-libre hacer
            avanza;
        norte;
        mientras frente-libre hacer
            avanza;
        sur;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        resultado (0);
    fin;
    inicia-ejecucion
        tendedero;
        apagate;
    termina-ejecucion
finalizar-programa