iniciar-programa

    define-nueva-instruccion orientar como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
    fin;

    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion orientar2 como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion orientar3 como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion dejar como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        deja-zumbador;
    fin;
    define-nueva-instruccion dejaa como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        avanza;
        si frente-bloqueado entonces inicio
            gira-derecha;
                mientras izquierda-bloqueada hacer avanza;
                gira-izquierda;
                avanza;
                gira-izquierda;
                avanza;
                mientras izquierda-bloqueada y frente-libre hacer avanza;
        fin
        sino inicio
            avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    fin;
    define-nueva-instruccion deja-abajo(n) como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        repetir n veces coge-zumbador;
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        si frente-libre entonces avanza;
    fin;
    define-nueva-instruccion deja-abajo-total(n) como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        gira-izquierda;
        si frente-libre entonces avanza;
        repetir n veces deja-zumbador;
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        si frente-libre entonces avanza;
        si frente-libre entonces avanza;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador y orientado-al-este entonces inicio
                coge-zumbador;

            fin
            sino inicio
                mientras no-orientado-al-sur hacer gira-izquierda;
            fin;
        fin;
        si orientado-al-sur entonces inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir n veces coge-zumbador;
            mientras no-orientado-al-este hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                comparar(n);
            fin;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                repetir n veces coge-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    comparar(n);
                fin;
            fin
            sino inicio
                deja-abajo(n);
                comparar(n);
            fin;
        fin;
    fin;

    define-nueva-instruccion color(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            color(sucede(n));
        fin
        sino inicio
            mientras no-junto-a-zumbador hacer avanza;
            gira-izquierda;
            gira-izquierda;
            gira-izquierda;
            comparar(n);
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si frente-libre entonces inicio
                avanza;
                cuenta(sucede(n));
            fin
            sino inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                cuenta(sucede(n));
            fin;
        fin
        sino inicio
            deja-abajo-total(n);
            si frente-libre entonces inicio
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                cuenta(0);
            fin
            sino si junto-a-zumbador entonces cuenta(0);
        fin;
    fin;
    define-nueva-instruccion cuenta-total(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador y orientado-al-este entonces inicio
                coge-zumbador;
            fin
            sino inicio
                mientras no-orientado-al-sur hacer gira-izquierda;
            fin;
        fin;

        si orientado-al-sur entonces inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            mientras no-orientado-al-este hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                cuenta-total(n);
            fin
            sino mientras no-orientado-al-norte hacer gira-izquierda;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            fin
            sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    mientras no-junto-a-zumbador y frente-libre hacer avanza;
                    cuenta-total(n);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta-total2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta-total2(sucede(n));
          si orientado-al-norte entonces inicio
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                avanza;
            fin
            sino inicio
                gira-izquierda;
                mientras derecha-bloqueada hacer avanza;
                gira-derecha;
                avanza;
                gira-derecha;
                avanza;
                mientras derecha-bloqueada y frente-libre hacer avanza;
                gira-izquierda;
                avanza;
            fin;
            mientras no-orientado-al-norte hacer gira-izquierda;
            coge-zumbador;
          fin;
        fin
        sino inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                cuenta-total(n);
            fin
            sino inicio
                mientras no-orientado-al-norte hacer gira-izquierda;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orientar;
        color(0);
        orientar2;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        cuenta(0);
        orientar3;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras orientado-al-este y (frente-libre o junto-a-zumbador) hacer cuenta-total2(0);
        dejaa;
        apagate;
    termina-ejecucion
finalizar-programa
