iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion av (z) como inicio
        repetir z veces inicio
            si frente-libre entonces inicio
            avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion portero (v) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            portero (sucede (v));
        fin
        sino inicio
            mientras frente-libre hacer inicio
                avanza;
            fin;
            gira (2);
            av (precede (v));
            deja-zumbador;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion alto (c) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            alto (sucede (c));
        fin
        sino inicio
            avanza;
            portero (0);
            av (precede (c));
            gira (2);
            deja-zumbador;
            mientras frente-libre hacer inicio
                avanza;
                deja-zumbador;
            fin;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion ancho (x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ancho (sucede (x));
        fin
        sino inicio
            avanza;
            alto (0);
            gira-izquierda;
            mientras orientado-al-norte hacer inicio
                si junto-a-zumbador entonces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin
                    sino inicio
                        gira (3);
                    fin;
                fin
                sino inicio
                    gira (2);
                    avanza;
                    gira-izquierda;
                fin;
            fin;
            mientras frente-libre hacer inicio
                repetir precede (x) veces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin;
                    deja-zumbador;
                fin;
                gira (2);
                av (precede (x));
                gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    gira-izquierda;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion salida como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira (3);
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira (3);
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira-izquierda;
        avanza;
    fin;
    define-nueva-instruccion conta (e) como inicio
        si frente-libre entonces inicio
            avanza;
            conta (sucede (e));
        fin
        sino inicio
            gira (2);
            av (e);
            avanza;
            repetir sucede (e) veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion contar (b) como inicio
        si no-junto-a-zumbador entonces inicio
            avanza;
            contar (sucede (b));
        fin
        sino inicio
            mientras orientado-al-oeste hacer inicio
                si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    gira (2);
                fin;
                si no-junto-a-zumbador entonces inicio
                    gira (2);
                    avanza;
                fin;
            fin;
            gira (2);
            av (b);
            si frente-libre entonces inicio
                salida;
                deja-zumbador;
                apagate;
            fin;
            salida;
            gira (2);
            avanza;
            conta (0);
        fin;
    fin;
    define-nueva-instruccion determina como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira (3);
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira (2);
        contar (0);
    fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
        avanza;
        avanza;
        avanza;
        gira (2);
        ancho (0);
        determina;
        apagate;
    termina-ejecucion
finalizar-programa
