iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion situa(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        situa(sucede(n));
    fin sino inicio
        oeste;
        mientras frente-libre hacer avanza;
        este;
        repetir n veces avanza;
        deja-zumbador;
    fin;
fin;
define-nueva-instruccion largo(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        largo(sucede(a));
    fin sino inicio
        mientras no-junto-a-zumbador hacer avanza;
        coge-zumbador;
        situa(0);
        repetir a veces inicio
            avanza;
        fin;
        deja-zumbador;
    fin;
fin;
define-nueva-instruccion lleva(b) como inicio
    si frente-libre y no-junto-a-zumbador entonces inicio
        avanza;
        lleva(sucede(b));
    fin sino inicio
        si frente-bloqueado entonces inicio
            repetir b veces deja-zumbador;
            sur;
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            lleva(0);
        fin sino inicio
            norte;
            avanza;
            este;
            mientras frente-libre hacer avanza;
            oeste;
            avanza;
            repetir b veces deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion contar como inicio
    si frente-libre entonces inicio
        avanza;
        contar;
        deja-zumbador;
    fin sino inicio
        sur;
        mientras frente-libre hacer avanza;
        este;
        avanza;
    fin;
fin;
define-nueva-instruccion compara como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        avanza;
        oeste;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            oeste;
            avanza;
            este;
            compara;
        fin sino inicio
            sur;
            mientras frente-libre hacer avanza;
            este;
            avanza;
            deja-zumbador;
            apagate;
        fin;
    fin sino inicio
        oeste;
        mientras frente-libre hacer avanza;
        este;
        contar;
        deja-zumbador;
    fin;
fin;
    inicia-ejecucion
    este;
    avanza;
    avanza;
    mientras junto-a-zumbador hacer coge-zumbador;
    avanza;
    oeste;
    coge-zumbador;
    largo(0);
    norte;
    avanza;
    este;
    lleva(0);
    este;
    compara;
        apagate;
    termina-ejecucion
finalizar-programa
