iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion portero(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           portero(sucede(n));
        fin
    sino
        inicio
            oeste;
        mientras frente-libre hacer avanza;
            este;
        si no si-es-cero (n) entonces repetir precede(n) veces avanza;
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
            oeste;
        mientras frente-libre hacer avanza;
            este;
            repetir 6 veces avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
        fin;
    fin;

define-nueva-instruccion ancho(x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ancho(sucede(x));
        fin
    sino
        inicio
            oeste;
        mientras frente-libre hacer avanza;
            norte;
            avanza;
            este;
        mientras no-junto-a-zumbador hacer avanza;
        repetir x veces
            inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

define-nueva-instruccion masAlejadoDerecha(n) como
    inicio
    si no-junto-a-zumbador entonces
        inicio
            avanza;
            masAlejadoDerecha(sucede(n));
        fin
    sino
        inicio
            sur;
            avanza;
            oeste;
        mientras frente-libre hacer avanza;
            este;
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;

define-nueva-instruccion masAlejadoIzquierda(n) como
    inicio
    si no-junto-a-zumbador entonces
        inicio
           avanza;
           masAlejadoIzquierda(sucede(n));
        fin
    sino
        inicio
            sur;
            avanza;
            oeste;
        mientras frente-libre hacer avanza;
            este;
            repetir n veces deja-zumbador;
        fin;
    fin;

define-nueva-instruccion mayor(n) como
    inicio
    si no si-es-cero (n) entonces
        inicio
        si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                mayor(precede(n));
            fin sino este;
        fin sino mientras junto-a-zumbador hacer coge-zumbador;
    fin;

define-nueva-instruccion compara(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            compara(sucede(n));
        fin
    sino
        inicio
            oeste;
            avanza;
            mayor(n);
        fin;
    fin;

define-nueva-instruccion mideDerecho (n) como
    inicio
    si frente-libre entonces
        inicio
            avanza;
            mideDerecho(sucede(n));
        fin
    sino
        inicio
            sur;
            avanza;
            este;
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;

define-nueva-instruccion arranca como
    inicio
        este;
        avanza;
        portero(0);
        ancho(0);
        oeste;
    mientras frente-libre hacer avanza;
        este;
        masAlejadoIzquierda(0);
        norte;
        avanza;
        este;
    mientras frente-libre hacer avanza;
        oeste;
        masAlejadoDerecha(0);
        compara(0);
    si orientado-al-este entonces
        inicio
            norte;
            avanza;
            este;
            mideDerecho(1);
        fin
    sino
        inicio
            norte;
            avanza;
            este;
        mientras frente-libre hacer avanza;
            sur;
            avanza;
            este;
            avanza;
            deja-zumbador;
        fin;
    fin;

    inicia-ejecucion
        arranca;
        apagate;
    termina-ejecucion
finalizar-programa

