iniciar-programa
    define-nueva-instruccion voltea como repetir 2 veces gira-izquierda;
    define-nueva-instruccion derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion ir como inicio
        avanza;
        mientras no junto-a-zumbador hacer avanza;
    fin;
    define-nueva-instruccion  c(n) como inicio
        si frente-libre entonces inicio
            avanza;
            c(sucede(n));
        fin sino inicio
            mientras no orientado-al-norte hacer gira-izquierda;
            repetir 2 veces inicio
                derecha;
                mientras frente-libre hacer avanza;
            fin;
            gira-izquierda;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir sucede (n) veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        repetir sucede (n) veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
        fin;
        mientras no orientado-al-oeste hacer gira-izquierda;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            deja-zumbador;
        fin sino inicio
            mientras  frente-libre hacer avanza;
            derecha;
            mientras frente-libre hacer avanza;
            derecha;
            c(0);
        fin;
     fin;
    define-nueva-instruccion revisa(n) como inicio
        si no junto-a-zumbador y frente-libre entonces inicio
            avanza;
            revisa(sucede(n));
        fin sino inicio
            derecha;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            avanza;
            compara(n);
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si no-junto-a-zumbador y frente-libre  entonces inicio
            avanza;
            cuenta(sucede(n));
        fin sino inicio
            si junto-a-zumbador o frente-bloqueado entonces inicio
                voltea;
                mientras frente-libre hacer avanza;
                derecha;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                avanza;
                repetir sucede(n) veces deja-zumbador;
                voltea;
                ir;
                derecha;
                mientras junto-a-zumbador y frente-libre hacer avanza;
                si no junto-a-zumbador entonces inicio
                    voltea;
                    avanza;
                fin;
                mientras no orientado-al-este hacer gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    revisa(0);
                fin sino inicio
                    derecha;
                    mientras frente-libre hacer avanza;
                    gira-izquierda;
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    deja-zumbador;
               fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion ancho(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ancho(sucede(n));
        fin sino inicio
            voltea;
            mientras no junto-a-zumbador hacer avanza;
            derecha;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            si no junto-a-zumbador entonces inicio
                voltea;
                avanza;
            fin;
            mientras no orientado-al-este hacer gira-izquierda;
            repetir precede(n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                    derecha;
                    mientras frente-libre hacer inicio
                        deja-zumbador;
                        avanza;
                    fin;
                    deja-zumbador;
                    voltea;
                    mientras junto-a-zumbador y frente-libre hacer avanza;
                    si no junto-a-zumbador entonces inicio
                        voltea;
                        avanza;
                    fin;
                    mientras no orientado-al-este hacer gira-izquierda;
                fin;
            fin;
            voltea;
            si frente-libre entonces inicio
                mientras junto-a-zumbador y frente-libre hacer avanza;
                si no junto-a-zumbador entonces inicio
                    cuenta(0);
                fin sino inicio
                    voltea;
                    mientras junto-a-zumbador y frente-libre hacer avanza;
                    revisa(0);
                fin;
            fin sino inicio
                voltea;
                c(0);
            fin;
       fin;
    fin;
    define-nueva-instruccion altura como inicio
        mientras junto-a-zumbador hacer coge-zumbador;
            voltea;
            mientras no junto-a-zumbador hacer avanza;
            derecha;
            mientras frente-libre hacer inicio
                avanza;
                deja-zumbador;
            fin;
            voltea;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            ir;
            ancho(0);
    fin;
    define-nueva-instruccion portero(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            portero(sucede(n));
        fin sino inicio
            voltea;
            mientras frente-libre hacer avanza;
            voltea;
            repetir precede(n) veces avanza;
                deja-zumbador;
                ir;
                altura;
        fin;
     fin;
    inicia-ejecucion
        derecha;
        avanza;
        portero(0);

        apagate;
    termina-ejecucion
finalizar-programa
