iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion portero(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            portero(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            si no si-es-cero(n) entonces repetir precede(n) veces avanza;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion altura(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            altura(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras no-junto-a-zumbador hacer avanza;
            gira(3);
            si no si-es-cero(n) entonces repetir precede(n) veces inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            si no-junto-a-zumbador entonces deja-zumbador;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            gira(1);
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion ancho(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ancho(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras no-junto-a-zumbador hacer avanza;
            gira(2);
            si no si-es-cero(n) entonces repetir precede(n) veces inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            si no-junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion arriba(n) como inicio
        si no si-es-cero(n) entonces inicio
            repetir precede(n) veces inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            si no-junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion llenar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llenar(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            mientras junto-a-zumbador hacer inicio
                arriba(n);
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                avanza;
                gira(1);
            fin;
        fin;
    fin;
    define-nueva-instruccion area como inicio
        gira(3);
        avanza;
        portero(0);
        avanza;
        mientras no-junto-a-zumbador hacer avanza;
        altura(0);
        gira(2);
        mientras frente-libre hacer avanza;
        gira(1);
        mientras no-junto-a-zumbador hacer avanza;
        ancho(0);
        gira(2);
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si junto-a-zumbador entonces avanza sino repetir 2 veces avanza;
        gira(1);
        avanza;
        llenar(0);
    fin;
    define-nueva-instruccion distancia1(n) como inicio
        si frente-libre entonces inicio
            si frente-libre entonces avanza;
            distancia1(sucede(n));
        fin;
        si frente-bloqueado entonces inicio
            gira(3);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            repetir sucede(n) veces deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion distancia2(n) como inicio
        si no-junto-a-zumbador entonces inicio
            si frente-libre entonces avanza;
            distancia2(sucede(n));
        fin;
        si junto-a-zumbador entonces inicio
            mientras frente-libre hacer avanza;
            gira(3);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            si no si-es-cero(n) entonces repetir n veces deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion mayor(n) como inicio
        si no-junto-a-zumbador entonces inicio
            si frente-libre entonces avanza;
            mayor(sucede(n));
        fin;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador y frente-libre hacer avanza;
            si no-junto-a-zumbador entonces inicio
                gira(2);
                avanza;
                gira(2);
            fin;
            repetir n veces inicio
                si frente-libre entonces avanza sino inicio
                    gira(3);
                    mientras frente-libre hacer avanza;
                    gira(1);
                    avanza;
                    deja-zumbador;
                    apagate;
                fin;
            fin;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            distancia1(0);
        fin;
    fin;
inicia-ejecucion
    area;
    gira(1);
    mientras no-junto-a-zumbador hacer avanza;
    mientras frente-libre y junto-a-zumbador hacer avanza;
    gira(2);
    mientras no-junto-a-zumbador hacer avanza;
    gira(1);
    mientras junto-a-zumbador y frente-libre hacer avanza;
    si no-junto-a-zumbador entonces inicio
        gira(2);
        avanza;
        gira(2);
    fin;
    si izquierda-bloqueada entonces inicio
        gira(3);
        distancia1(0);
    fin sino inicio
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
        mayor(0);
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
