iniciar-programa

define-nueva-instruccion gira-d como repetir 3 veces gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanza-muro como mientras frente-libre hacer avanza;
define-nueva-instruccion avanza-zumbador como mientras junto-a-zumbador hacer avanza;

define-nueva-instruccion portero como
inicio
    si junto-a-zumbador y orientado-al-este entonces
    inicio
        coge-zumbador;
        portero;
        sur;
        avanza-muro;
        este;
        avanza;
        deja-zumbador;
    fin
    sino inicio
        si no-junto-a-zumbador y orientado-al-este entonces
        inicio
            oeste;
            avanza;
            norte;
            portero;
        fin
        sino inicio
            si junto-a-zumbador y orientado-al-norte entonces
            inicio
                coge-zumbador;
                portero;
                norte;
                avanza;
                deja-zumbador;
            fin
            sino inicio
                si no-junto-a-zumbador y orientado-al-norte entonces
                inicio
                    oeste;
                    avanza;
                    portero;
                fin
                sino inicio
                    si junto-a-zumbador y orientado-al-oeste entonces
                    inicio
                        coge-zumbador;
                        portero;
                        avanza;
                    fin
                    sino inicio
                        si no junto-a-zumbador y orientado-al-oeste entonces
                        inicio
                            oeste;
                            avanza-muro;
                            este;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion area como
inicio
    mientras junto-a-zumbador hacer
    inicio
        norte;
        si frente-libre entonces
        inicio
            avanza;
            oeste;
            avanza;
            si junto-a-zumbador entonces
            inicio
                este;
                avanza;
                deja-zumbador;
            fin
            sino inicio
                este;
                avanza;
                sur;
                avanza-muro;
                este;
                avanza;
            fin;
        fin
        sino inicio
            sur;
            avanza-muro;
            este;
            avanza;
        fin;

    fin;
fin;

define-nueva-instruccion columna-izq como
inicio
    si no-junto-a-zumbador entonces
    inicio
        avanza;
        columna-izq;
        deja-zumbador;
    fin
    sino inicio
        norte;
        avanza;
        este;
        avanza-muro;
        sur;
        avanza-muro;
        este;
        avanza;
        norte;
        avanza;
    fin;
fin;

define-nueva-instruccion columna-der como
inicio
    si no-junto-a-zumbador entonces
    inicio
        avanza;
        columna-der;
        deja-zumbador;
    fin
    sino inicio
        norte;
        avanza;
        este;
        avanza-muro;
        sur;
        avanza;
        este;
        avanza;
        norte;
        repetir 2 veces avanza;
    fin;
fin;

define-nueva-instruccion der como
inicio
    si frente-libre entonces
    inicio
        avanza;
        der;
        deja-zumbador;
    fin
    sino inicio
        norte;
        avanza;
        este;
        avanza-muro;
        sur;
        avanza;
        este;
        avanza;
    fin;
fin;

define-nueva-instruccion izq como
inicio
    sur;
    avanza-muro;
fin;

define-nueva-instruccion comparar como
inicio
    mientras junto-a-zumbador hacer
    inicio
        coge-zumbador;
        sur;
        avanza;
        si junto-a-zumbador entonces coge-zumbador;
        norte;
        avanza;
    fin;
    sur;
    avanza;
    si no-junto-a-zumbador entonces
    inicio
        sur;
        avanza-muro;
        oeste;
        avanza;
        der;
    fin
    sino inicio
        izq;
    fin;
fin;

    inicia-ejecucion
        este;
        avanza;
        coge-zumbador;
        avanza;
        coge-zumbador;
        avanza;
        coge-zumbador;
        portero;
        sur;
        avanza-muro;
        oeste;
        avanza-muro;
        norte;
        avanza;
        este;
        mientras no-junto-a-zumbador hacer avanza;
        sur;
        avanza;
        deja-zumbador;
        este;
        avanza;
        area;
        oeste;
        avanza-muro;
        este;
        columna-izq;
        sur;
        avanza;
        oeste;
        avanza;
        columna-der;
        comparar;
        deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
