iniciar-programa
    define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion posicionate como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        posicionate;
        avanza;
      fin sino inicio
        mientras frente-libre hacer inicio
          avanza;
        fin;
        este;
      fin;
    fin;

    define-nueva-instruccion posicionate2 como inicio
      posicionate;
      oeste;
      avanza;
    fin;

    define-nueva-instruccion altura como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        altura;
        si frente-libre entonces inicio
          deja-zumbador;
          avanza;
        fin sino inicio
          deja-zumbador;
        fin;
      fin sino inicio
        avanza;
        posicionate2;
        norte;
      fin;
    fin;

    define-nueva-instruccion altura2 como inicio
      altura;
      sur;
      mientras frente-libre hacer inicio
        avanza;
      fin;
      este;
    fin;

    define-nueva-instruccion anchura como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        anchura;
        si no-junto-a-zumbador entonces inicio
          deja-zumbador;
          avanza;
        fin sino inicio
          avanza;
        fin;
      fin sino inicio
        avanza;
        altura2;
      fin;
    fin;

    define-nueva-instruccion traza como inicio
      este;
      repetir 3 veces inicio
        avanza;
      fin;
      oeste;
      anchura;
    fin;

    define-nueva-instruccion llena como inicio
       oeste;
       avanza;
       si junto-a-zumbador entonces inicio
         este;
         avanza;
         si no-junto-a-zumbador entonces inicio
           deja-zumbador;
         fin;
       fin sino inicio
         este;
         avanza;
       fin;
       norte;
    fin;

    define-nueva-instruccion checa3 como inicio
      norte;
      mientras frente-libre hacer inicio
        llena;
        avanza;
      fin;
      llena;
    fin;

    define-nueva-instruccion checa2 como inicio
      mientras junto-a-zumbador hacer inicio
        checa3;
        sur;
        mientras frente-libre hacer inicio
          avanza;
        fin;
        este;
        avanza;
      fin;
    fin;

    define-nueva-instruccion checa como inicio
      oeste;
      mientras frente-libre hacer inicio
        avanza;
      fin;
      este;
      mientras no-junto-a-zumbador hacer inicio
        avanza;
      fin;
      avanza;
      checa2;
    fin;

    define-nueva-instruccion cuenta como inicio
      si frente-libre entonces inicio
        avanza;
        cuenta;
        deja-zumbador;
      fin sino inicio
        sur;
        avanza;
        este;
        avanza;
      fin;
    fin;


    define-nueva-instruccion buscalo2 como inicio
      si no-junto-a-zumbador y frente-libre entonces inicio
        avanza;
        buscalo2;
        si no-junto-a-zumbador entonces inicio
          avanza;
        fin;
      fin sino inicio
        mientras frente-libre hacer inicio
          avanza;
        fin;
        oeste;
      fin;
    fin;


    define-nueva-instruccion buscalo como inicio
      si no-junto-a-zumbador entonces inicio
        buscalo2;
        si no-junto-a-zumbador entonces inicio
          mientras frente-libre hacer inicio
            avanza;
          fin;
          este;
          cuenta;
          deja-zumbador;
          apagate;
        fin sino inicio
          este;
          mientras frente-libre hacer inicio
            avanza;
          fin;
          sur;
          avanza;
          este;
          avanza;
          deja-zumbador;
          apagate;
        fin;
      fin sino inicio
        cuenta;
        deja-zumbador;
        apagate;
      fin;
    fin;

    define-nueva-instruccion compara como inicio
      oeste;
      mientras frente-libre hacer inicio
        avanza;
      fin;
      norte;
      avanza;
      este;
      buscalo;
    fin;

    inicia-ejecucion
        traza;
        checa;
        compara;
        apagate;
    termina-ejecucion
finalizar-programa
