iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;

    define-nueva-instruccion posicion(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            posicion(sucede(x));
        fin sino inicio
            oeste;
            corre;
            este;
            repetir precede(x) veces avanza;
        fin;
    fin;

    define-nueva-instruccion distancia como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            distancia;
            deja-zumbador;
            si frente-libre entonces avanza;
        fin sino inicio
            oeste;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            norte;
            corre;
            este;
        fin;
    fin;

    define-nueva-instruccion derecha como inicio
        si frente-libre entonces inicio
            avanza;
            derecha;
        fin sino inicio
            sur;
            corre;
            este;
            avanza;
        fin;
        deja-zumbador;
    fin;

    define-nueva-instruccion izquierda como inicio
        corre;
        sur;
        corre;
        este;
        avanza;
        deja-zumbador;
    fin;

    define-nueva-instruccion comparar(espacios) como inicio
        si no-junto-a-zumbador y frente-libre entonces inicio
            si orientado-al-oeste entonces inicio
                avanza;
                comparar(sucede(espacios));
            fin sino inicio
                si no si-es-cero(espacios) entonces inicio
                    avanza;
                    comparar(precede(espacios));
                fin sino inicio
                    izquierda;
                fin;
            fin;
        fin sino inicio
            si orientado-al-oeste entonces inicio
                corre;
                este;
                comparar(espacios);
            fin sino inicio
                si si-es-cero(espacios) entonces inicio
                    izquierda;
                fin sino inicio
                    oeste;
                    corre;
                    este;
                    derecha;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        posicion(0);
        deja-zumbador;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        avanza;
        distancia;
        corre;
        oeste;
        comparar(0);
        apagate;
    termina-ejecucion
finalizar-programa
