iniciar-programa
    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion orientar como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        media-vuelta;
    fin;
    define-nueva-instruccion pocicion como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pocicion;
            si orientado-al-norte entonces inicio
                gira-derecha;
                sal-de-instruccion;
            fin;
            avanza;
        fin
        sino inicio
            mientras frente-libre hacer avanza;
            gira-derecha;
        fin;
    fin;
    define-nueva-instruccion altura como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            altura;
            si orientado-al-oeste entonces inicio
                gira-derecha;
                sal-de-instruccion;
            fin;
            avanza;
            deja-zumbador;
        fin
        sino inicio
            mientras frente-libre y no junto-a-zumbador hacer avanza;
        fin;
    fin;
    define-nueva-instruccion ancho como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ancho;
            si orientado-al-oeste entonces inicio
                media-vuelta;
                sal-de-instruccion;
            fin;
            avanza;
            deja-zumbador;
        fin
        sino inicio
            mientras frente-libre y no junto-a-zumbador hacer avanza;
        fin;
    fin;
    define-nueva-instruccion gol-izquierda como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        avanza;
        gira-izquierda;
        avanza;
        deja-zumbador;
    fin;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
            camina;
        fin
        sino inicio
            gira-derecha;
            avanza;
            gira-izquierda;
            avanza;
        fin;
        deja-zumbador;
    fin;
    define-nueva-instruccion gol-derecha como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        gira-derecha;
        camina;
    fin;
    define-nueva-instruccion comparar como inicio
        si junto-a-zumbador entonces inicio
            media-vuelta;
            mientras junto-a-zumbador y frente-libre hacer avanza;
        fin
        sino inicio
            si orientado-al-norte entonces inicio
                gira-izquierda;
                comparar;
                si frente-libre y orientado-al-este entonces inicio
                    avanza;
                fin
                sino inicio
                    si orientado-al-este entonces inicio
                        mientras no-orientado-al-norte hacer gira-izquierda;
                    fin
                    sino inicio
                        sal-de-instruccion;
                    fin;
                fin;
            fin
            sino inicio
                si frente-libre entonces inicio
                    avanza;
                    comparar;
                    si frente-libre y orientado-al-este entonces inicio
                    avanza;
                fin
                sino inicio
                    si orientado-al-este entonces inicio
                        mientras no-orientado-al-norte hacer gira-izquierda;
                    fin
                    sino inicio
                        sal-de-instruccion;
                    fin;
                fin;
                fin
                sino inicio
                    media-vuelta;
                    mientras no-junto-a-zumbador hacer avanza;
                    mientras junto-a-zumbador hacer avanza;
                    media-vuelta;
                    avanza;
                    gira-derecha;
                    avanza;
                    gira-derecha;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orientar;
        pocicion;
        deja-zumbador;
        orientar;
        altura;
        orientar;
        ancho;
        media-vuelta;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira-derecha;
        comparar;
        si orientado-al-norte entonces inicio
            gol-izquierda;
        fin
        sino inicio
            gol-derecha;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
