iniciar-programa
define-nueva-instruccion gira(a) como
    repetir a veces gira-izquierda;
define-nueva-instruccion busca(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        busca(sucede(x));
    fin
    sino inicio
        gira(3);
        repetir x veces deja-zumbador;
        avanza;
        repetir x veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin
            sino inicio
                gira(2);
                avanza;
                gira(3);
                avanza;
                mientras no junto-a-zumbador hacer avanza;
                busca(0);
            fin;
        fin;
        si no junto-a-zumbador entonces inicio
            mientras frente-libre hacer avanza;
            gira(3);
            mientras frente-libre hacer avanza;
            repetir x veces deja-zumbador;
            apagate;
        fin
        sino apagate;
    fin;
fin;
define-nueva-instruccion paso(p) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        paso(p);
        deja-zumbador;
        repetir p veces avanza;
        deja-zumbador;
        gira(2);
        repetir p veces avanza;
        gira(2);
    fin;
fin;
define-nueva-instruccion conejo(c) como inicio
  si junto-a-zumbador entonces inicio
        coge-zumbador;
        conejo(sucede(c));
    fin
    sino inicio
        repetir 2 veces avanza;
        gira(3);
        mientras frente-libre hacer inicio
            repetir c veces inicio
              si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    gira(2);
                    mientras frente-libre hacer avanza;
                    gira(2);
                    mientras no junto-a-zumbador hacer avanza;
                    busca(0);
                fin;
            fin;
            gira(2);
            repetir c veces avanza;
            gira(2);
            paso(c);
            repetir c veces avanza;
            deja-zumbador;
        fin;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
        mientras no junto-a-zumbador hacer avanza;
        busca(0);
    fin;
fin;
define-nueva-instruccion tortuga(t) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        tortuga(sucede(t));
    fin
    sino inicio
        repetir 2 veces avanza;
        gira(3);
        mientras no junto-a-zumbador hacer avanza;
        coge-zumbador;
        mientras frente-libre hacer inicio
            repetir t veces inicio
                si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    gira(3);
                    avanza;
                    gira(3);
                    mientras frente-libre hacer avanza;
                    gira(3);
                    conejo(0);
                fin;
            fin;
            gira(2);
            repetir t veces avanza;
            gira(2);
            paso(t);
            repetir t veces avanza;
            deja-zumbador;
        fin;
        gira(3);
        avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(3);
        conejo(0);
    fin;
fin;
    inicia-ejecucion
    avanza;
    tortuga(0);
        apagate;
    termina-ejecucion
finalizar-programa
