iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(n));
        fin;
        si no-junto-a-zumbador y orientado-al-norte entonces inicio
            repetir 2 veces avanza;
            gira(3);
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion conejo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            conejo(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion tortuga(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tortuga(sucede(n));
        fin;
        si no-junto-a-zumbador y orientado-al-este entonces inicio
            repetir n veces avanza;
            repetir n veces deja-zumbador;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            gira(1);
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
        fin;
    fin;
    define-nueva-instruccion contador(n) como inicio
        si orientado-al-norte entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                gira(1);
                mientras frente-libre hacer avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                repetir n veces deja-zumbador;
                apagate;
            fin sino inicio
                gira(2);
                avanza;
                gira(1);
            fin;
        fin;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
        repetir 3 veces avanza;
        gira(3);
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        mientras junto-a-zumbador hacer inicio
            tortuga(0);
            conejo(0);
            gira(1);
            contador(sucede(n));
        fin;
    fin;
    inicia-ejecucion
    mientras no-orientado-al-norte hacer gira-izquierda;
    avanza;
    contar(0);
    contador(0);
        apagate;
    termina-ejecucion
finalizar-programa
