iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierdA;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierdA;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierdA;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierdA;

    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin;
            mientras no junto-a-zumbador hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion marcar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            marcar(sucede(n));
        fin sino inicio
            avanza;
            avanza;
            este;
            mientras no junto-a-zumbador hacer inicio
                avanza;
            fin;
            coge-zumbador;
            mientras frente-libre hacer inicio
                repetir n veces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin;
                fin;
                si no junto-a-zumbador entonces inicio
                    deja-zumbador;
                    oeste;
                    repetir n veces inicio
                        avanza;
                    fin;
                    este;
                    contar(0);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion procedimiento como inicio
        norte;
        repetir 4 veces inicio
            avanza;
        fin;
        deja-zumbador;
        sur;
        repetir 3 veces inicio
            avanza;
        fin;
        norte;
        marcar(0);
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        avanza;
        norte;
        marcar(0);
        sur;
        avanza;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        mientras no junto-a-zumbador hacer inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion llevar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llevar;
            deja-zumbador;
        fin sino inicio
            sur;
            avanza;
            avanza;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion checa(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            checa(precede(n));
        fin sino inicio
            si si-es-cero(n) y no junto-a-zumbador entonces inicio
                sur;
                avanza;
                avanza;
                llevar;
                apagate;
            fin;
            si no si-es-cero(n) entonces inicio
                sur;
                avanza;
                este;
                mientras frente-libre y no junto-a-zumbador hacer inicio
                    avanza;
                fin;
            fin;
            si si-es-cero(n) y junto-a-zumbador entonces inicio
                sur;
                avanza;
                este;
                mientras frente-libre y no junto-a-zumbador hacer inicio
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            comparar(sucede(n));
        fin sino inicio
            sur;
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
            norte;
            avanza;
            avanza;
            checa(n);
        fin;
    fin;

    inicia-ejecucion
        procedimiento;
        mientras junto-a-zumbador hacer inicio
            comparar(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
