iniciar-programa
    define-nueva-instruccion media-vuelta como
        repetir 2 veces
            gira-izquierda;
    define-nueva-instruccion gira-derecha como
        repetir 3 veces
            gira-izquierda;
    define-nueva-instruccion recoge como
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge;
            deja-zumbador;
        fin
        sino
            repetir 2 veces
                avanza;
     define-nueva-instruccion recoge2 como
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge2;
            deja-zumbador;
        fin
        sino inicio
            repetir 2 veces
                avanza;
            gira-derecha;
            mientras no-junto-a-zumbador hacer inicio
                deja-zumbador;
                avanza;
           fin;
           coge-zumbador;
        fin;
    define-nueva-instruccion carrera como
        si junto-a-zumbador y no-orientado-al-sur entonces inicio
            coge-zumbador;
            carrera;
            si frente-libre y no-orientado-al-sur entonces inicio
                avanza;
                deja-zumbador;
            fin
            sino
                si no-orientado-al-sur entonces
                    gira-derecha;
        fin;
    define-nueva-instruccion acumula como
        si junto-a-zumbador entonces inicio
            avanza;
            acumula;
            deja-zumbador;
        fin
        sino inicio
            media-vuelta;
            avanza;
            mientras junto-a-zumbador y frente-libre hacer
                avanza;
            media-vuelta;
            si no-junto-a-zumbador entonces
                avanza;
        fin;
    define-nueva-instruccion camino como
        si no-orientado-al-sur entonces inicio
            mientras junto-a-zumbador hacer
                avanza;
            media-vuelta;
            avanza;
            media-vuelta;
            carrera;
            si orientado-al-sur entonces
                sal-de-instruccion;
            media-vuelta;
            avanza;
            acumula;
            mientras frente-libre hacer inicio
                si no-junto-a-zumbador entonces
                    deja-zumbador;
                avanza;
            fin;
            si no-junto-a-zumbador entonces
                deja-zumbador;
            gira-izquierda;
            avanza;
            gira-izquierda;
            mientras junto-a-zumbador y frente-libre hacer
                avanza;
            si no-junto-a-zumbador entonces inicio
                media-vuelta;
                avanza;
                media-vuelta;
            fin;
            carrera;
            si orientado-al-sur entonces
                sal-de-instruccion;
            media-vuelta;
            avanza;
            acumula;
            gira-derecha;
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                    media-vuelta
                sino inicio
                    deja-zumbador;
                     media-vuelta;
                    avanza;
                    gira-derecha;
                    mientras frente-libre hacer inicio
                        si no-junto-a-zumbador entonces
                            deja-zumbador;
                        avanza;
                    fin;
                    gira-derecha;
                    avanza;
                    gira-derecha;
               fin;
           fin
           sino inicio
                media-vuelta;
                avanza;
                gira-derecha;
                mientras frente-libre hacer inicio
                    si no-junto-a-zumbador entonces
                        deja-zumbador;
                    avanza;
                fin;
                gira-derecha;
                avanza;
                gira-derecha;
           fin;
           camino;
           deja-zumbador;
        fin
        sino inicio
            mientras frente-libre hacer
                avanza;
            gira-derecha;
            mientras frente-libre hacer
                avanza;
        fin;
    inicia-ejecucion
    repetir 2 veces
        avanza;
    recoge;
    media-vuelta;
    repetir 3 veces
        avanza;
    media-vuelta;
    recoge2;
    media-vuelta;
    mientras frente-libre hacer
        avanza;
    gira-derecha;
    avanza;
    gira-derecha;
    camino;
        apagate;
    termina-ejecucion
finalizar-programa
