iniciar-programa
  define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer inicio
          gira-izquierda;
      fin;
  fin;
  define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer inicio
          gira-izquierda;
      fin;
  fin;
  define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer inicio
          gira-izquierda;
      fin;
  fin;
  define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer inicio
          gira-izquierda;
      fin;
  fin;
  define-nueva-instruccion al-frente como inicio
      mientras frente-libre hacer inicio
          avanza;
      fin;
  fin;
  define-nueva-instruccion esq-inf-izq como inicio
      sur;
      al-frente;
      oeste;
      al-frente;
      norte;
  fin;
  define-nueva-instruccion camina como inicio
      si frente-libre entonces inicio
          avanza;
      fin sino inicio
          si derecha-libre entonces inicio
              norte;
              avanza;
              este;
              al-frente;
              oeste;
          fin sino inicio
              sur;
          fin;
      fin;
  fin;
  define-nueva-instruccion aumenta como inicio
      si frente-libre entonces inicio
          avanzA;
          aumenta;
          avanzA;
      fin sino inicio
          repetir 2 veces gira-izquierda;
          deja-zumbador;
      fin;
  fin;
  define-nueva-instruccion mide-cuarto como inicio
      si no-junto-a-zumbador entonces inicio
          deja-zumbador;
          oeste;
          aumenta;
          norte;
          si frente-libre entonces inicio
              avanza;
              mide-cuarto;
              sur;
              avanza;
          fin;
          sur;
          si frente-libre entonces inicio
              avanza;
              mide-cuarto;
              norte;
              avanza;
          fin;
          este;
          si frente-libre entonces inicio
              avanza;
              mide-cuarto;
              oeste;
              avanza;
          fin;
          oeste;
          si frente-libre entonces inicio
              avanza;
              mide-cuarto;
              este;
              avanza;
          fin;
      fin;
  fin;
  define-nueva-instruccion compara(n) como inicio
      si junto-a-zumbador y no si-es-cero (n) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
      fin sino inicio
          si no si-es-cero (n) entonces inicio
                  (*ES Mayor N*)
              repetir n veces inicio
                  deja-zumbador;
              fin;
          fin;
      fin;
  fin;
  define-nueva-instruccion recoge(n) como inicio
      si junto-a-zumbador y frente-libre entonces inicio
          coge-zumbador;
          recoge(sucede(n));
      fin sino inicio
          si frente-libre entonces inicio
              avanza;
              recoge(n);
          fin sino inicio
              compara(n);

          fin;
      fin;
  fin;
  define-nueva-instruccion recoge-medida como inicio
      oeste;
      al-frente;
      norte;
      mientras junto-a-zumbador y frente-libre hacer inicio
          avanza;
      fin;
      sur;
      recoge(0);
  fin;
  define-nueva-instruccion busca-ceros como inicio
      mientras no-orientado-al-sur hacer inicio
          mientras no-junto-a-zumbador y frente-libre hacer inicio
              avanza;
              si frente-bloqueado entonces inicio
                  apagate;
              fin;
          fin;
          mientras junto-a-zumbador hacer inicio
              camina;
          fin;
          si frente-libre entonces inicio
                  (*ESTOY EN UN CUARTO*)
              mide-cuarto;
              recoge-medida;
              norte;
              avanza;
              avanza;
              este;
              al-frente;
              oeste;
          fin sino inicio
                  (*ESTOY FUERA DEL SOTANO*)
                  camina;
          fin;
      fin;
  fin;

    inicia-ejecucion
        avanza;
        avanza;
        este;
        al-frente;
        oeste;
        busca-ceros;
        apagate;
    termina-ejecucion
finalizar-programa
