iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como inicio
        mientras no orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
    fin;

    define-nueva-instruccion ubicate como inicio
        este;
        si frente-libre entonces inicio
            avanza;
        fin;
        norte;
        si frente-libre entonces inicio
            avanza;
            si no junto-a-zumbador entonces inicio
                ir11;
                apagate;
            fin;
        fin;
        mientras junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
        fin;
        sur;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si frente-bloqueado y no junto-a-zumbador entonces inicio
            ir11;
            apagate;
        fin;
    fin;

    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            repetir precede(n) veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    repetir n veces inicio
                        deja-zumbador;
                    fin;
                    sal-de-instruccion;
                fin sino inicio
                    deja-zumbador;
                    repetir precede(n) veces inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
            si no junto-a-zumbador entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
                sal-de-instruccion;
            fin;
        fin;
        si si-es-cero(precede(n)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    sal-de-instruccion;
                fin sino inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresa como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                media-vuelta;
                avanza;
                sal-de-instruccion;
            fin;
            regresa;
            deja-zumbador;
        fin sino inicio
            media-vuelta;
            avanza;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino inicio
            deja-zumbador;
            ir11;
            si junto-a-zumbador entonces inicio
                compara(n);
            fin sino inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion monte-alban2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                sal-de-instruccion;
            fin;
            media-vuelta;
            si frente-libre entonces inicio
                avanza;
                deja-zumbador;
                regresa;
            fin;
            norte;
            si frente-libre entonces inicio
                avanza;
                monte-alban2;
                sur;
                avanza;
                media-vuelta;
                avanza;
                regresa;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                monte-alban2;
                norte;
                avanza;
                media-vuelta;
                avanza;
                regresa;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                monte-alban2;
                oeste;
                avanza;
                media-vuelta;
                avanza;
                regresa;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                monte-alban2;
                este;
                avanza;
                media-vuelta;
                avanza;
                regresa;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    busca2;
                fin;
            fin sino inicio
                deja-zumbador;
                monte-alban2;
            fin;
        fin;
        si frente-bloqueado y no junto-a-zumbador entonces inicio
            norte;
            avanza;
            mientras junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;    
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                ir11;
                oeste;
                apagate;
            fin;
            sur;
            mientras no junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si frente-bloqueado y no junto-a-zumbador entonces inicio
                ir11;
                oeste;
                apagate;
            fin;
            busca2;
        fin;
    fin;

    define-nueva-instruccion busca como inicio
        mientras junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si frente-bloqueado y no junto-a-zumbador entonces inicio
            norte;
            avanza;
            mientras junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                ir11;
                oeste;
                sal-de-instruccion;
            fin;
            sur;
            mientras no junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si frente-bloqueado y no junto-a-zumbador entonces inicio
                ir11;
                oeste;
                sal-de-instruccion;
            fin;
            mientras junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            busca;
        fin;
    fin;

    define-nueva-instruccion monte-alban como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                sal-de-instruccion;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                monte-alban;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                monte-alban;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                monte-alban;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                monte-alban;
                este;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        norte;
        mientras no orientado-al-oeste hacer inicio
            ir11;
            ubicate;
            busca;
            si no orientado-al-oeste entonces inicio
                monte-alban;
            fin;
        fin;
        mientras no orientado-al-este hacer inicio
            ir11;
            ubicate;
            busca2;
            coge-zumbador;
            cuenta(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
