iniciar-programa
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion rellenar(a) como inicio
       repetir a veces inicio
           si junto-a-zumbador entonces inicio
               coge-zumbador;
           fin;
           avanza;
           si no-junto-a-zumbador entonces inicio
               deja-zumbador;
               deja-zumbador;
               deja-zumbador;
           fin sino inicio
               coge-zumbador;
           fin;
       fin;
       sur;
       repetir a veces inicio
           avanza;
       fin;
       este;
       si frente-libre entonces inicio
           avanza;
           norte;
           si junto-a-zumbador entonces inicio
               rellenar(a);
               si orientado-al-este entonces inicio
                    norte;
                    repetir a veces inicio
                        avanza;
                    fin;
                    deja-zumbador;
                    sur;
                    repetir a veces inicio
                        avanza;
                    fin;
                    oeste;
               fin;
           fin sino inicio
               este;
           fin;
       fin;
    fin;
    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            si frente-libre entonces inicio
                avanza;
            fin;
            contar(sucede(n));
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                sur;
                repetir n veces inicio
                    avanza;
                fin;
                norte;
                rellenar(precede(n));
            fin sino inicio
                sur;
                repetir n veces inicio
                    avanza;
                fin;
                norte;
                rellenar(n);
            fin;
        fin;
    fin;
    define-nueva-instruccion juntar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar;
            deja-zumbador;
        fin sino inicio
            gira-izquierda;
            gira-izquierda;
            avanza;
        fin;
    fin;
    define-nueva-instruccion traer como inicio
        gira-izquierda;
        gira-izquierda;
        si frente-libre entonces inicio
            avanza;
            juntar;
        fin;
    fin;
    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            traer;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                sur;
                avanza;
                traer;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                norte;
                avanza;
                traer;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                oeste;
                avanza;
                traer;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                este;
                avanza;
                traer;
            fin;
        fin;
    fin;
    define-nueva-instruccion ir112(n) como inicio
        sur;
        si frente-libre entonces inicio
            avanza;
            ir112(n);
            norte;
            avanza;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                repetir n veces inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                    fin;
                fin;
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion ir11(n) como inicio
        oeste;
        si frente-libre entonces inicio
            avanza;
            ir11(n);
            este;
            avanza;
        fin sino inicio
            ir112(n);
        fin;
    fin;
    define-nueva-instruccion lleva(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lleva(sucede(n));
        fin sino inicio
            ir11(n);
        fin;
    fin;
    define-nueva-instruccion revisar(a) como inicio
        mientras no-junto-a-zumbador hacer inicio
            mientras no-junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si junto-a-zumbador entonces inicio
                busqueda;
                lleva(0);
                oeste;
                revisar(a);
            fin sino inicio
                este;
                repetir a veces inicio
                    avanza;
                fin;
                norte;
                avanza;
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion contaracostado(n) como inicio
        si frente-libre entonces inicio
            avanza;
            contaracostado(sucede(n));
        fin sino inicio
            este;
            repetir n veces inicio
                avanza;
            fin;
            norte;
            avanza;
            oeste;
            revisar(n);
        fin;
    fin;
    inicia-ejecucion
        avanza;
        este;
        avanza;
        norte;
        contar(0);
        contaracostado(0);
        apagate;
    termina-ejecucion
finalizar-programa

