iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ve-esquina como inicio
        norte;
        corre;
        este;
        avanza;
        sur;
        mientras no-junto-a-zumbador hacer avanza;
        este;
        corre;
        oeste;
        mientras no-junto-a-zumbador hacer avanza;
    fin;
    define-nueva-instruccion cuenta-pasos(x) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta-pasos(x);
            avanza;
        fin sino inicio
            sur;
            deja-zumbador;
            corre;
            repetir x veces si junto-a-zumbador entonces coge-zumbador;
            repetir x veces deja-zumbador;
            norte;
            avanza;
            mientras no-junto-a-zumbador hacer avanza;
            este;
            coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        repetir 2 veces gira-izquierda;
        avanza;
    fin;
    define-nueva-instruccion suma-actuales(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            suma-actuales(sucede(x));
        fin sino inicio
            regresa;
            repetir x veces deja-zumbador;
            regresa;
        fin;
    fin;
    define-prototipo-instruccion rellena;
    define-nueva-instruccion camina como inicio
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                rellena;
                repetir 2 veces gira-izquierda;
                avanza;
                repetir 2 veces gira-izquierda;
            fin;
            gira-izquierda;
        fin;
    fin;
    define-prototipo-instruccion visita;
    define-nueva-instruccion camina2 como inicio
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                visita;
                repetir 2 veces gira-izquierda;
                avanza;
                repetir 2 veces gira-izquierda;
            fin;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion visita como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            camina2;
        fin;
    fin;
    define-nueva-instruccion mayor(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(x));
        fin sino inicio
            oeste;
            cuenta-pasos(x);
        fin;
    fin;
    define-nueva-instruccion rellena como inicio
        si no-junto-a-zumbador entonces inicio
            regresa;
            deja-zumbador;
            regresa;
            camina;
            suma-actuales(0);
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion explora como inicio
        mientras frente-libre hacer inicio
            oeste;
            mientras frente-libre hacer inicio
                si no-junto-a-zumbador entonces inicio
                    camina;
                    deja-zumbador;
                    mayor(0);
                    deja-zumbador;
                    oeste;
                fin sino inicio
                    avanza
                fin;
            fin;
            este;
            avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            oeste;
            si no-junto-a-zumbador entonces  avanza;
            sur;
            avanza;
        fin;
    fin;
    inicia-ejecucion
        ve-esquina;
        sur;
        explora;
        apagate;
    termina-ejecucion
finalizar-programa
