iniciar-programa
    define-prototipo-instruccion rodea;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion delinea como inicio
        avanza;
        este;
        avanza;
        mientras junto-a-zumbador hacer inicio
            avanza;
        fin;
        oeste;
        avanza;
        norte;
        mientras junto-a-zumbador hacer inicio
            avanza;
        fin;
        este;
        avanza;
        oeste;
        mientras frente-libre hacer inicio
            repetir 3 veces deja-zumbador;
            avanza;
        fin;
        repetir 3 veces deja-zumbador;
        este;
        mientras junto-a-zumbador hacer avanza;
        oeste;
        avanza;
        sur;
        mientras frente-libre hacer inicio
            avanza;
            repetir 3 veces deja-zumbador
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        avanza;
        este;
        avanza;
        norte;
    fin;
    define-nueva-instruccion rellena como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    rellena;
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion compara(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            si no junto-a-zumbador entonces inicio
                repetir x veces deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    deja-zumbador;
                    sur;
                    mientras frente-libre hacer avanza;
                    este;
                    avanza;
                    norte;
                    avanza;
                    si no junto-a-zumbador entonces inicio
                        oeste;
                        mientras frente-libre hacer avanza;
                        sur;
                        avanza;
                        compara(n);
                        norte;
                        avanza;
                        este;
                        avanza;
                        norte;
                        rodea;
                    fin sino inicio
                        recoge(n);
                    fin;
                fin sino inicio
                    deja-zumbador;
                    avanza;
                    recoge(sucede(n));
                fin;
            fin sino inicio
                deja-zumbador;
                avanza;
                recoge(n);
            fin;
        fin sino inicio
            avanza;
            recoge(n);
        fin;
    fin;
    define-nueva-instruccion rodea como inicio
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    este;
                    avanza;
                    si no-junto-a-zumbador entonces inicio
                        apagate;
                    fin sino inicio
                        sur;
                        mientras frente-libre hacer avanza;
                        norte;
                        avanza;
                    fin;
                fin sino inicio
                    deja-zumbador;
                    si frente-libre y junto-a-zumbador entonces inicio
                        si junto-a-zumbador entonces inicio
                            coge-zumbador;
                            si junto-a-zumbador entonces inicio
                                deja-zumbador;
                                sur;
                                mientras frente-libre hacer avanza;
                                este;
                                avanza;
                                norte;
                                avanza;
                            fin sino inicio
                                deja-zumbador;
                                avanza;
                            fin;
                        fin;
                    fin sino inicio
                        rellena;
                        sur;
                        mientras frente-libre hacer avanza;
                        oeste;
                        mientras frente-libre hacer avanza;
                        norte;
                        avanza;
                        este;
                        avanza;
                        norte;
                        recoge(0);
                    fin;
                fin;
            fin sino inicio
                rellena;
                sur;
                mientras frente-libre hacer avanza;
                oeste;
                mientras frente-libre hacer avanza;
                norte;
                avanza;
                este;
                avanza;
                norte;
                recoge(0);
            fin;
        fin;
    fin;
    inicia-ejecucion
        delinea;
        rodea;
        apagate;
    termina-ejecucion
finalizar-programa
