iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion llega11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion mapa como inicio
        avanza;
        gira(3);
        avanza;
        gira(1);
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(n));
        fin sino inicio
            avanza;
            repetir n veces si junto-a-zumbador entonces coge-zumbador;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion pared2 como inicio
        si frente-libre entonces inicio
            avanza;
            pared2;
            avanza;
        fin sino inicio
            gira(2);
            avanza;
            deja-zumbador;
            gira(2);
            avanza;
            gira(2);
        fin;
    fin;

    define-nueva-instruccion pared como inicio
        si frente-libre entonces inicio
            avanza;
            pared;
            avanza;
        fin sino inicio
            gira(1);
            pared2;
            gira(3);
        fin;
    fin;

    define-nueva-instruccion pared4 como inicio
        si frente-libre entonces inicio
            avanza;
            pared4;
            avanza;
        fin sino inicio
            gira(2);
            avanza;
            gira(2);
            compara(0);
            gira(2);
        fin;
    fin;

    define-nueva-instruccion pared3 como inicio
        si frente-libre entonces inicio
            avanza;
            pared3;
            avanza;
        fin sino inicio
            gira(1);
            pared4;
            gira(3);
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;

            oeste;
            pared;

            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                sur;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                oeste;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                norte;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                sur;
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    este;
                    busqueda(1);
                    oeste;
                    pared3;
                fin sino inicio
                    norte;
                    avanza;
                    este;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recorre como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recorre;
            deja-zumbador;
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            si frente-libre entonces avanza;
            gira(3);
            avanza;
            norte;
        fin;
    fin;

    define-nueva-instruccion explora como inicio
        mientras (junto-a-zumbador y frente-libre) hacer inicio
            avanza;
            gira(3);
            mientras frente-libre y junto-a-zumbador hacer paso;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            avanza;
            norte;
        fin;
    fin;

    inicia-ejecucion
        mapa;
        explora;
        llega11;
        apagate;
    termina-ejecucion
finalizar-programa
