iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion orientar como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
    fin;
    define-nueva-instruccion orienta como inicio
        norte;
        avanza;
        este;
        avanza;
        norte;
        mientras junto-a-zumbador y frente-libre hacer
            avanza;
        gira(2);
        avanza;
        este;
        mientras junto-a-zumbador y frente-libre hacer
            avanza;
        gira(2);
        avanza;
        sur;
    fin;
    define-nueva-instruccion comparar(n) como inicio
        repetir n veces
            si junto-a-zumbador entonces
                coge-zumbador;
        repetir n veces
            deja-zumbador;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino inicio
            deja-zumbador;
            orientar;
            si junto-a-zumbador entonces inicio
                comparar(precede(n));
            fin
            sino inicio
                repetir precede(n) veces
                    deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion checa(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            checa(sucede(n));
        fin
        sino inicio
            deja-zumbador;
            avanza;
            repetir precede(n) veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
           coge-zumbador;
           si no-junto-a-zumbador entonces
               deja-zumbador;

        fin
        sino inicio
            deja-zumbador;
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    busqueda;
                fin;
                sur;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        checa(1);
                    fin
                    sino inicio
                        deja-zumbador;
                        avanza;
                    fin;
                fin
                sino inicio
                    checa(0);
                fin;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    busqueda;
                fin;
                oeste;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        checa(1);
                    fin
                    sino inicio
                        deja-zumbador;
                        avanza;
                    fin;
                fin
                sino inicio
                    checa(0);
                fin;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    busqueda;
                fin;
                norte;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        checa(1);
                    fin
                    sino inicio
                        deja-zumbador;
                        avanza;
                    fin;
                fin
                sino inicio
                    checa(0);
                fin;
            fin;
            oeste;
                si frente-libre entonces inicio
                    avanza;
                si no-junto-a-zumbador entonces inicio
                    busqueda;
                fin;
                este;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        checa(1);
                    fin
                    sino inicio
                        deja-zumbador;
                        avanza;
                    fin;
                fin
                sino inicio
                    checa(0);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion menu como inicio
        si junto-a-zumbador entonces inicio
            oeste;
            mientras frente-libre  hacer inicio
                si no-junto-a-zumbador entonces inicio
                    busqueda;
                    cuenta(0);
                    orienta;
                fin
                sino inicio
                    avanza;
                fin;
            fin;
            gira(2);
            avanza;
            mientras junto-a-zumbador hacer
                avanza;
            gira(2);
            avanza;
            sur;
            avanza;
            menu;
        fin;
    fin;
    define-nueva-instruccion men como inicio
        orienta;
        menu;
    fin;
    inicia-ejecucion
        men;
        menu;
        apagate;
    termina-ejecucion
finalizar-programa
