iniciar-programa
define-prototipo-instruccion busqueda;
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion pasa como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pasa;
        deja-zumbador;
    fin sino inicio
        deja-zumbador;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;
define-nueva-instruccion adelante como inicio
    si frente-libre entonces avanza;
    si no junto-a-zumbador entonces inicio
        busqueda;
        coge-zumbador;
        pasa;
    fin sino inicio
        gira(2);
        avanza;
        gira(2);
    fin;
fin;
define-nueva-instruccion izquierda como inicio
    gira(1);
    si frente-libre entonces avanza;
    si no junto-a-zumbador entonces inicio
        busqueda;
        coge-zumbador;
        pasa;
        gira(3);
    fin sino inicio
        gira(2);
        avanza;
        gira(1);
    fin;
fin;
define-nueva-instruccion derecha como inicio
    gira(3);
    si frente-libre entonces avanza;
    si no junto-a-zumbador entonces inicio
        busqueda;
        coge-zumbador;
        pasa;
        gira(1);
    fin sino inicio
        gira(2);
        avanza;
        gira(3);
    fin;
fin;
define-nueva-instruccion busqueda como inicio
    si no junto-a-zumbador entonces inicio
        repetir 2 veces deja-zumbador;
        adelante;
        izquierda;
        derecha;
    fin;
fin;
define-nueva-instruccion posicion como inicio
        mientras no orientado-al-este hacer gira-izquierda;
        avanza;
        gira(1);
        si frente-libre entonces avanzA;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        mientras no junto-a-zumbador y frente-libre hacer avanza;
fin;
define-nueva-instruccion compara(x) como inicio
    si no si-es-cero(x) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            compara(precede(x));
            deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin sino inicio
        deja-zumbador;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            compara(x);
        fin sino inicio
            repetir x veces deja-zumbador;
        fin;
    fin;
fin;
    inicia-ejecucion
        posicion;
        mientras junto-a-zumbador  hacer inicio
            mientras junto-a-zumbador y frente-libre hacer avanza;
            si no junto-a-zumbador y frente-libre entonces inicio
                busqueda;
                coge-zumbador;
                cuenta(0);
                posicion;
            fin sino inicio
                gira(2);
                si frente-libre entonces avanza;
                mientras junto-a-zumbador y frente-libre hacer avanza;
                gira(3);
                si frente-libre entonces inicio
                    avanza;
                    gira(3);
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                fin;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
