iniciar-programa

    define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer inicio
        gira-izquierda;
      fin;
    fin;


    define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion ubicar como inicio
      norte;
      avanza;
      este;
      avanza;
      norte;
    fin;


    define-nueva-instruccion esquina como inicio
      ubicar;
      mientras junto-a-zumbador hacer inicio
         avanza;
      fin;
      sur;
      avanza;
      este;
      mientras junto-a-zumbador hacer inicio
         avanza;
      fin;
    fin;

    define-nueva-instruccion pone2 como inicio
      mientras frente-libre hacer inicio
        deja-zumbador;
        deja-zumbador;
        avanza;
      fin;
        deja-zumbador;
        deja-zumbador;
    fin;

    define-nueva-instruccion pintaAbajo como inicio
      sur;
      pone2;
      oeste;
      avanza;
      pone2;
    fin;

    define-nueva-instruccion pintaArriba como inicio
      oeste;
      pone2;
      sur;
      avanza;
      pone2;
      coge-zumbador;
      coge-zumbador;
    fin;

    define-nueva-instruccion delimita como inicio
      esquina;
      pintaAbajo;
      esquina;
      oeste;
      avanza;
      norte;
      avanza;
      oeste;
      pintaArriba;
    fin;
    define-nueva-instruccion iniciar como inicio
      esquina;
      oeste;
      avanza;
      sur;
      mientras no-junto-a-zumbador hacer inicio
         avanza;
      fin;
    fin;

    define-nueva-instruccion buscaIni como inicio
      norte;
      mientras junto-a-zumbador hacer inicio
         avanza;
      fin;
      sur;
      avanza;
      este;
      mientras junto-a-zumbador hacer inicio
         avanza;
      fin;
      sur;
      mientras no-junto-a-zumbador hacer inicio
         avanza;
      fin;
    fin;

    define-nueva-instruccion arrastraAdela como inicio
      si junto-a-zumbador entonces inicio
         coge-zumbador;
         arrastraAdela;
         deja-zumbador;
      fin sino inicio
        deja-zumbador;
        gira-izquierda;
        gira-izquierda;
        avanza;
      fin;

    fin;

    define-nueva-instruccion arrastraRegreso(n) como inicio
      si junto-a-zumbador entonces inicio
         coge-zumbador;
         arrastraRegreso(n);
         deja-zumbador;
      fin sino inicio
        deja-zumbador;
        si si-es-cero(n) entonces inicio
          sur;
        fin;
        si si-es-cero(precede(n)) entonces inicio
          norte;
        fin;
        si si-es-cero(precede(precede(n))) entonces inicio
          oeste;
        fin;
        si si-es-cero(precede(precede(precede(n)))) entonces inicio
          este;
        fin;
        avanza;
        coge-zumbador;
      fin;

    fin;

    define-nueva-instruccion busca(n) como inicio
     si no-junto-a-zumbador entonces inicio
        si si-es-cero(n) entonces inicio
           deja-zumbador;
        fin sino inicio
          gira-izquierda;
          gira-izquierda;
          avanza;
          deja-zumbador;
          arrastraAdela;
        fin;
      fin;
      norte;
      avanza;
      si no-junto-a-zumbador entonces inicio
         busca(1);
         arrastraRegreso(0);
      fin sino inicio
        sur;
        avanza;
      fin;
      sur;
      avanza;
      si no-junto-a-zumbador entonces inicio
         busca(1);
         arrastraRegreso(1);
      fin sino inicio
         norte;
         avanza;
      fin;
      este;
      avanza;
      si no-junto-a-zumbador entonces inicio
         busca(1);
         arrastraRegreso(2);
      fin sino inicio
         oeste;
         avanza;
      fin;
      oeste;
      avanza;
      si no-junto-a-zumbador  entonces inicio
         busca(1);
         arrastraRegreso(3);
      fin sino inicio
         este;
         avanza;
      fin;

    fin;

    define-nueva-instruccion ir11 como inicio
      oeste;
      mientras frente-libre hacer inicio
         avanza;
      fin;
      sur;
      mientras frente-libre hacer inicio
         avanza;
      fin;
    fin;

    define-nueva-instruccion masgrande(n) como inicio
      repetir n veces inicio
        si junto-a-zumbador entonces inicio
           coge-zumbador;
        fin;
      fin;
      repetir n veces inicio
         deja-zumbador;
      fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
      si junto-a-zumbador entonces inicio
         coge-zumbador;
         compara( sucede(n) );
      fin sino inicio
        deja-zumbador;
        ir11;
        masgrande(n);
      fin;
    fin;

    define-nueva-instruccion buscaLinea como inicio
      mientras frente-libre y junto-a-zumbador hacer inicio
          avanza;
          si no-junto-a-zumbador entonces inicio
             busca(0);
             compara(0);
             buscaIni;
             oeste;
          fin;
      fin;
      si frente-bloqueado entonces inicio
        este;
        mientras junto-a-zumbador hacer inicio
           avanza;
        fin;
        oeste;
        avanza;
        sur;
        coge-zumbador;
        coge-zumbador;
      fin;

    fin;

inicia-ejecucion
    delimita;
    iniciar;
    mientras frente-libre hacer inicio
      oeste;
      buscaLinea;
      avanza;
    fin;
    apagate;
termina-ejecucion
finalizar-programa

